media-libs/lilv: fix minimum dep versions

Closes: https://bugs.gentoo.org/888105
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 74 insertions, 0 deletions

diff --git a/media-libs/lilv/lilv-0.24.20-r1.ebuild b/media-libs/lilv/lilv-0.24.20-r1.ebuild
new file mode 100644
index 000000000000..bf2102322e3e
--- /dev/null
+++ b/media-libs/lilv/lilv-0.24.20-r1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_REQ_USE='threads(+)'
+
+inherit meson-multilib python-single-r1
+
+DESCRIPTION="Library to make the use of LV2 plugins as simple as possible for applications"
+HOMEPAGE="https://drobilla.net/software/lilv.html"
+SRC_URI="https://download.drobilla.net/${P}.tar.xz"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ppc ppc64 ~riscv ~sparc x86"
+IUSE="doc python test tools"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? (
+		app-doc/doxygen
+		dev-python/sphinx
+		dev-python/sphinx_lv2_theme
+	)
+"
+RDEPEND="
+	${PYTHON_DEPS}
+	>=dev-libs/serd-0.30.10[${MULTILIB_USEDEP}]
+	>=dev-libs/sord-0.16.10[${MULTILIB_USEDEP}]
+	media-libs/libsndfile
+	>=media-libs/lv2-1.18.2[${MULTILIB_USEDEP}]
+	>=media-libs/sratom-0.6.10[${MULTILIB_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+
+pkg_setup() {
+	python_setup
+}
+
+src_prepare() {
+	default
+
+	# fix doc installation path
+	sed -iE "s%install_dir: docdir / 'lilv-0',%install_dir: docdir / '${PF}',%g" doc/c/meson.build || die
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		$(meson_native_use_feature doc docs)
+		$(meson_feature python bindings_py)
+		$(meson_feature test tests)
+		$(meson_feature tools)
+	)
+
+	meson_src_configure
+}
+
+multilib_src_install() {
+	meson_src_install
+	python_optimize
+}
+
+multilib_src_install_all() {
+	local DOCS=( AUTHORS NEWS README.md )
+	einstalldocs
+
+	newenvd - 60lv2 <<-EOF
+		LV2_PATH=${EPREFIX}/usr/$(get_libdir)/lv2
+	EOF
+}