media-libs/openglide: New package for emulating Glide

The original upstream is dead but I have been contributing to a fork
on GitHub that's being maintained by another Gentoo user.

Package-Manager: portage-2.3.0

1 files changed, 62 insertions, 0 deletions

diff --git a/media-libs/openglide/openglide-0.09_rc9_p20160913.ebuild b/media-libs/openglide/openglide-0.09_rc9_p20160913.ebuild
new file mode 100644
index 000000000000..15df0a8dfdc9
--- /dev/null
+++ b/media-libs/openglide/openglide-0.09_rc9_p20160913.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+COMMIT="3722fc563b737d2d7933df6a771651c2154e6f7b"
+
+inherit autotools eutils multilib-minimal
+
+DESCRIPTION="A Glide to OpenGL wrapper"
+HOMEPAGE="http://openglide.sourceforge.net/"
+SRC_URI="https://github.com/voyageur/${PN}/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+sdl static-libs"
+
+RDEPEND="virtual/glu:=[${MULTILIB_USEDEP}]
+	virtual/opengl:=[${MULTILIB_USEDEP}]
+	sdl? (
+		media-libs/libsdl:=[${MULTILIB_USEDEP}]
+	)
+	!sdl? (
+		x11-libs/libICE:=[${MULTILIB_USEDEP}]
+		x11-libs/libSM:=[${MULTILIB_USEDEP}]
+		x11-libs/libXxf86vm:=[${MULTILIB_USEDEP}]
+	)"
+
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/${PN}-${COMMIT}"
+ECONF_SOURCE="${S}"
+
+MULTILIB_WRAPPED_HEADERS=(
+	/usr/include/openglide/sdk2_unix.h
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+multilib_src_configure() {
+	econf \
+		--enable-shared \
+		--disable-sdltest \
+		$(use_enable sdl) \
+		$(use_enable static-libs static)
+}
+
+multilib_src_install_all() {
+	insinto /etc
+	doins "${FILESDIR}"/OpenGLid.ini
+
+	exeinto /usr/share/${PN}
+	newexe platform/dosbox/glide2x.ovl glide2x-dosbox.ovl
+	newexe platform/dosemu/glide2x.ovl glide2x-dosemu.ovl
+
+	prune_libtool_files
+	einstalldocs
+}