media-libs/vulkan-loader: Bump to 1.2.162 and drop old

Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Nick Sarnie <sarnex@gentoo.org>

3 files changed, 68 insertions, 1 deletions

diff --git a/media-libs/vulkan-loader/Manifest b/media-libs/vulkan-loader/Manifest
index 14ef402e7848..58795351c93e 100644
--- a/media-libs/vulkan-loader/Manifest
+++ b/media-libs/vulkan-loader/Manifest
@@ -1 +1,2 @@
 DIST vulkan-loader-1.2.154.tar.gz 1417349 BLAKE2B b134932b31325884639e94ef74f7b97c9111554ef904777df9b4e398d927e89bdf2394593ce8e4483e9fda1cd1f299df0841471ac11263580b04bc97786ac973 SHA512 003f16bff7eb24791e458b757d0fee5db9ab68d6e7b56eae623af0c4702c534cc19099c79d2ec2493cd3c30c796f1dff060bc3aaa4057b9215749de65566c157
+DIST vulkan-loader-1.2.162.tar.gz 1421710 BLAKE2B 94b739821c5a12a94a52d8f0a9d79c13055ef3b45b907d53b82325b7be13db52b77d01397534e939bed5629d7a405ff8a09f8da374274a066986b4126fae9863 SHA512 89a99f282b73ec59dde30e4c8c09056b40416185a14ff9b7f7bd496754840e5ac764e7624f1f9a0f11792e786b00f19c3c9e55ccbb22a3c501d8ea9e815d84f9
diff --git a/media-libs/vulkan-loader/vulkan-loader-1.2.162.ebuild b/media-libs/vulkan-loader/vulkan-loader-1.2.162.ebuild
new file mode 100644
index 000000000000..f3ce3e6251b5
--- /dev/null
+++ b/media-libs/vulkan-loader/vulkan-loader-1.2.162.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN=Vulkan-Loader
+CMAKE_ECLASS="cmake"
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+inherit flag-o-matic cmake-multilib python-any-r1 toolchain-funcs
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/KhronosGroup/${MY_PN}.git"
+	EGIT_SUBMODULES=()
+	inherit git-r3
+else
+	SRC_URI="https://github.com/KhronosGroup/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+	S="${WORKDIR}"/${MY_PN}-${PV}
+fi
+
+DESCRIPTION="Vulkan Installable Client Driver (ICD) Loader"
+HOMEPAGE="https://github.com/KhronosGroup/Vulkan-Loader"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="layers wayland X"
+
+BDEPEND=">=dev-util/cmake-3.10.2"
+DEPEND="${PYTHON_DEPS}
+	~dev-util/vulkan-headers-${PV}
+	wayland? ( dev-libs/wayland:=[${MULTILIB_USEDEP}] )
+	X? (
+		x11-libs/libX11:=[${MULTILIB_USEDEP}]
+		x11-libs/libXrandr:=[${MULTILIB_USEDEP}]
+	)
+"
+PDEPEND="layers? ( media-libs/vulkan-layers:=[${MULTILIB_USEDEP}] )"
+
+multilib_src_configure() {
+	# Integrated clang assembler doesn't work with x86 - Bug #698164
+	if tc-is-clang && [[ ${ABI} == x86 ]]; then
+		append-cflags -fno-integrated-as
+	fi
+
+	local mycmakeargs=(
+		-DCMAKE_SKIP_RPATH=ON
+		-DBUILD_TESTS=OFF
+		-DBUILD_LOADER=ON
+		-DBUILD_WSI_WAYLAND_SUPPORT=$(usex wayland)
+		-DBUILD_WSI_XCB_SUPPORT=$(usex X)
+		-DBUILD_WSI_XLIB_SUPPORT=$(usex X)
+		-DVULKAN_HEADERS_INSTALL_DIR="${ESYSROOT}/usr"
+	)
+	cmake_src_configure
+}
+
+multilib_src_install() {
+	keepdir /etc/vulkan/icd.d
+
+	cmake_src_install
+}
+
+pkg_postinst() {
+	einfo "USE=demos has been dropped as per upstream packaging"
+	einfo "vulkaninfo is now available in the dev-util/vulkan-tools package"
+}
diff --git a/media-libs/vulkan-loader/vulkan-loader-9999.ebuild b/media-libs/vulkan-loader/vulkan-loader-9999.ebuild
index bb006a7a4f3a..05922ef1a74f 100644
--- a/media-libs/vulkan-loader/vulkan-loader-9999.ebuild
+++ b/media-libs/vulkan-loader/vulkan-loader-9999.ebuild
@@ -5,7 +5,7 @@ EAPI=7
 
 MY_PN=Vulkan-Loader
 CMAKE_ECLASS="cmake"
-PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_COMPAT=( python3_{6,7,8,9} )
 inherit flag-o-matic cmake-multilib python-any-r1 toolchain-funcs
 
 if [[ ${PV} == *9999* ]]; then