media-libs/vulkan-tools: Initial version

Package-Manager: Portage-2.3.40, Repoman-2.3.9

1 files changed, 49 insertions, 0 deletions

diff --git a/media-libs/vulkan-tools/vulkan-tools-9999.ebuild b/media-libs/vulkan-tools/vulkan-tools-9999.ebuild
new file mode 100644
index 000000000000..d009fa4f314a
--- /dev/null
+++ b/media-libs/vulkan-tools/vulkan-tools-9999.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python3_{4,5,6} )
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/KhronosGroup/Vulkan-Tools.git"
+	EGIT_SUBMODULES=()
+	inherit git-r3
+else
+	EGIT_COMMIT="51dfb7b8a19820d6716190dd7e45cd6e861e1f1a"
+	KEYWORDS="~amd64"
+	SRC_URI="https://github.com/KhronosGroup/Vulkan-Tools/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/Vulkan-Tools-${EGIT_COMMIT}"
+fi
+
+inherit python-any-r1 cmake-multilib
+
+DESCRIPTION="Official Vulkan Tools and Utilities for Windows, Linux, Android, and MacOS"
+HOMEPAGE="https://github.com/KhronosGroup/Vulkan-Tools"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="X wayland"
+
+RDEPEND=""
+DEPEND="${PYTHON_DEPS}
+	dev-util/glslang:=[${MULTILIB_USEDEP}]
+	dev-util/vulkan-headers
+	wayland? ( dev-libs/wayland:=[${MULTILIB_USEDEP}] )
+	X? (
+		x11-libs/libX11:=[${MULTILIB_USEDEP}]
+		x11-libs/libXrandr:=[${MULTILIB_USEDEP}]
+	   )"
+
+PATCHES=( "${FILESDIR}/${PN}-Use-usr-for-vulkan-headers.patch" )
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_SKIP_RPATH=True
+		-DBUILD_WSI_MIR_SUPPORT=False
+		-DBUILD_WSI_WAYLAND_SUPPORT=$(usex wayland)
+		-DBUILD_WSI_XCB_SUPPORT=$(usex X)
+		-DBUILD_WSI_XLIB_SUPPORT=$(usex X)
+		-DGLSLANG_INSTALL_DIR="/usr"
+	)
+	cmake-utils_src_configure
+}