media-libs/libmediainfo: version bump to 0.7.94

2 files changed, 84 insertions, 0 deletions

diff --git a/media-libs/libmediainfo/Manifest b/media-libs/libmediainfo/Manifest
index 8153b1b0d379..4bead54bf82d 100644
--- a/media-libs/libmediainfo/Manifest
+++ b/media-libs/libmediainfo/Manifest
@@ -1,2 +1,3 @@
 DIST libmediainfo_0.7.91.tar.xz 1575876 SHA256 28818b88cedc8d5bc6b6c2a32d37ec456cb9784b4bf105416ef1e5821a6769c0 SHA512 7b05ae099cd8fd1f1f4134a16cff407bd6016095bad8769444f14eecd34b3771634c9a59f4fb41b04f5fc0381cf755ef1d5cbd05fd0bee57fcafacbb52293f5c WHIRLPOOL f86664ce7931f08f17370ece5e20669a3762ab9cc51532dfd00ce05b0081335863795bb9de966566bf006076a579b3f23023ab40804f07355e57c4b6ece66c51
 DIST libmediainfo_0.7.92.1.tar.xz 1582960 SHA256 200d4d7c52b6b3c1bed455e75fbc5b899b0c74846eab45e368388c74a2250e2e SHA512 9924eb9f4abdac4ea0ce92808d1fbcd3f40503dead7a1c1fc0a58cc1ce8b4db2e805db5921bc3eaf62a8cfd8b14b41e14e94ec96ae0b22421fab61bbf83eab8b WHIRLPOOL 152d94c9fe42a0ca4643398e7676c56169b477cead53f39dc0b9cfa57f9080251e616cc90f17ed36503e76ef3dabcf3ef8cb7fc4cc6984c9571c69bc98c9ec92
+DIST libmediainfo_0.7.94.tar.xz 1591624 SHA256 10e7926373611815e494ff00ee0fc8766076b4f241da153a9baf7dfa029cad32 SHA512 80a71b84e4799dd1057cc9f44695bff4b4e468cea3c99a068d4abde1e07b534901100fd05a79071c2d96aa104111f8ed7e6e462f2355b097efe4671743ffaa43 WHIRLPOOL 08484fed520fff31eefa01d7b7fb35516d7d07e9770e8cf0841becb52a500ac05e9d24a110e2193d7445d4755cffe3fe35871a991e64833d00b46ad28204c401
diff --git a/media-libs/libmediainfo/libmediainfo-0.7.94.ebuild b/media-libs/libmediainfo/libmediainfo-0.7.94.ebuild
new file mode 100644
index 000000000000..1c094fcc2519
--- /dev/null
+++ b/media-libs/libmediainfo/libmediainfo-0.7.94.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools eutils flag-o-matic
+
+MY_PN="MediaInfo"
+DESCRIPTION="MediaInfo libraries"
+HOMEPAGE="http://mediaarea.net/mediainfo/"
+SRC_URI="http://mediaarea.net/download/source/${PN}/${PV}/${P/-/_}.tar.xz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="curl doc mms static-libs"
+
+RDEPEND="sys-libs/zlib
+	dev-libs/tinyxml2:=
+	>=media-libs/libzen-0.4.34[static-libs=]
+	curl? ( net-misc/curl )
+	mms? ( >=media-libs/libmms-0.6.1[static-libs=] )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )"
+
+# tests try to fetch data from online sources
+RESTRICT="test"
+
+S=${WORKDIR}/${MY_PN}Lib/Project/GNU/Library
+
+src_prepare() {
+	eapply -p4 "${FILESDIR}"/${PN}-0.7.63-pkgconfig.patch
+	eapply_user
+
+	sed -i 's:-O2::' configure.ac || die
+	append-cppflags -DMEDIAINFO_LIBMMS_DESCRIBE_SUPPORT=0
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-shared \
+		--with-libtinyxml2 \
+		$(use_with curl libcurl) \
+		$(use_with mms libmms) \
+		$(use_enable static-libs static) \
+		$(use_enable static-libs staticlibs)
+}
+
+src_compile() {
+	default
+
+	if use doc; then
+		cd "${WORKDIR}"/${MY_PN}Lib/Source/Doc
+		doxygen Doxyfile || die
+	fi
+}
+
+src_install() {
+	if use doc; then
+		local HTML_DOCS=( "${WORKDIR}"/${MY_PN}Lib/Doc/*.html )
+	fi
+
+	default
+
+	edos2unix ${PN}.pc #414545
+	insinto /usr/$(get_libdir)/pkgconfig
+	doins ${PN}.pc
+
+	for x in ./ Archive Audio Duplicate Export Image Multiple Reader Tag Text Video; do
+		insinto /usr/include/${MY_PN}/${x}
+		doins "${WORKDIR}"/${MY_PN}Lib/Source/${MY_PN}/${x}/*.h
+	done
+
+	insinto /usr/include/${MY_PN}DLL
+	doins "${WORKDIR}"/${MY_PN}Lib/Source/${MY_PN}DLL/*.h
+
+	dodoc "${WORKDIR}"/${MY_PN}Lib/*.txt
+
+	prune_libtool_files
+}