media-*/audacious*: version bump

3 files changed, 178 insertions, 0 deletions

diff --git a/media-plugins/audacious-plugins/Manifest b/media-plugins/audacious-plugins/Manifest
index c25d94e065d2..f02008cc184b 100644
--- a/media-plugins/audacious-plugins/Manifest
+++ b/media-plugins/audacious-plugins/Manifest
@@ -3,3 +3,5 @@ DIST audacious-plugins-3.6.2-gtk3.tar.bz2 1788886 SHA256 943d94c1ea09817caba627b
 DIST audacious-plugins-3.6.2.tar.bz2 1786338 SHA256 e7798936249e1601177503d148a3dd59edd289579f3f1667351eb0ba463642e8 SHA512 d0715bdc819b115e55daafc6715a770a9e2d8d61d19b9a9485195774e8ace672144dc7852f71bd0b796d26bfcb82766252f65d58a2a061e7a0228a1dda3148c5 WHIRLPOOL 055be62da6c7f8ddacf2c3ef18194ba09bf63dc3699919f6e5068740c0fc6db2b370da999ffe8724e62c60363928ae87ca86d526458fa93b9a3cce37799b12af
 DIST audacious-plugins-3.7.1-gtk3.tar.bz2 1838067 SHA256 75469b52694fcfce237a937c6c64c0d355aefa6a7b6c2504ab447d901afc073f SHA512 77b0e3c167d430ed97dfb2bd344d856de9a384a4667f7759ad59f47706de12d7b5b849455c381c27a58f82d3b423d08e922ac81f5e1bb0dd763b9a09bc3e53c6 WHIRLPOOL fbbc8e4a512b681ff2a87ea7c971b3496ff007dab5fdb534457e5608724ba43fc71642384a417190ded19d900b6e1dc20c1369f59882d91791bbcc637402c4a3
 DIST audacious-plugins-3.7.1.tar.bz2 1838045 SHA256 228a384f26afb000099166776d3454539956aa00fde90dcb4612ce8910ed4116 SHA512 2d22131babba572af235ec5f27135061a1602be55a2f709e327b7cd4052f7c11bc31398d01574a6f07197daa6b79cb42d5fa7b26f75764680420a46aede5cd9a WHIRLPOOL 026c355c6323aa6b56b09c119d9320ec5a7306f11b90504631f8a25c05b4f9bd1641ff223e0122a7b5be48f341a3820b759d1829ca60274285cfe19897c9edae
+DIST audacious-plugins-3.8.2-gtk3.tar.bz2 1821924 SHA256 7849024beae61b8af3874b166cf3977905aec77859e53901158b531b31ef0cef SHA512 a5457cecc72ca4d57a3fad686b5ff42b2110d8ef65203fa49ad063c8944fc41af5d231b0870126e21c4cc8b3152de36c13726813075d26ba86450ef2132a6d33 WHIRLPOOL 0a75dd8a439dd30dce4764385fa60f317c521c3f45b5e4ae6c1d14f6a677774854d4c1650ba59facc7d204cbd53b7a8b3fca8dd94ee1b040fc2c8f444b179e4f
+DIST audacious-plugins-3.8.2.tar.bz2 1821558 SHA256 d7cefca7a0e32bf4e58bb6e84df157268b5e9a6771a0e8c2da98b03f92a5fdd4 SHA512 61be2ee962853ed05366d4089ae1bef96c282ff61a947dc32f06651a9b620035a33cf4d75f4c4d74821099f36f9124f2b2266940f4844d14ca43ef70a81cde08 WHIRLPOOL 9d87947da3a7d90f0e5262d27dcbbbff2cfc833d340e87448a11d7c5fdfd5a64d8e1f49823a50e7f6ff33214a93594051e561e75eab422aa6321402067076e75
diff --git a/media-plugins/audacious-plugins/audacious-plugins-3.8.2.ebuild b/media-plugins/audacious-plugins/audacious-plugins-3.8.2.ebuild
new file mode 100644
index 000000000000..716ae4cc937c
--- /dev/null
+++ b/media-plugins/audacious-plugins/audacious-plugins-3.8.2.ebuild
@@ -0,0 +1,175 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+inherit eutils
+
+MY_P="${P/_/-}"
+S="${WORKDIR}/${MY_P}"
+DESCRIPTION="Audacious Player - Your music, your way, no exceptions"
+HOMEPAGE="http://audacious-media-player.org/"
+SRC_URI="!gtk3? ( http://distfiles.audacious-media-player.org/${MY_P}.tar.bz2 )
+	 gtk3? ( http://distfiles.audacious-media-player.org/${MY_P}-gtk3.tar.bz2 )"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="aac +adplug alsa aosd bs2b cdda cue ffmpeg flac fluidsynth gnome http gtk gtk3 jack
+lame libnotify libsamplerate lirc mms mp3 nls pulseaudio qt5 scrobbler sdl sid sndfile vorbis wavpack"
+REQUIRED_USE="
+	^^ ( gtk gtk3 qt5 )
+"
+# The following plugins REQUIRE a GUI build of audacious, because non-GUI
+# builds do NOT install the libaudgui library & headers.
+# Plugins without a configure option:
+#   alarm
+#   albumart
+#   delete-files
+#   ladspa
+#   playlist-manager
+#   search-tool
+#   skins
+#   vtx
+# Plugins with a configure option:
+#   glspectrum
+#   gtkui
+#   hotkey
+#   notify
+#   statusicon
+
+RDEPEND="app-arch/unzip
+	>=dev-libs/dbus-glib-0.60
+	dev-libs/libxml2:2
+	media-libs/libmodplug
+	~media-sound/audacious-${PV}
+	>=media-sound/audacious-3.7.1-r1
+	media-libs/adplug
+	( || ( >=dev-libs/glib-2.32.2[utils] dev-util/gdbus-codegen ) )
+	aac? ( >=media-libs/faad2-2.7 )
+	alsa? ( >=media-libs/alsa-lib-1.0.16 )
+	aosd? ( x11-libs/libXrender
+		x11-libs/libXcomposite )
+	bs2b? ( media-libs/libbs2b )
+	cdda? ( >=media-libs/libcddb-1.2.1
+		dev-libs/libcdio-paranoia )
+	cue? ( media-libs/libcue )
+	ffmpeg? ( >=virtual/ffmpeg-0.7.3 )
+	flac? ( >=media-libs/libvorbis-1.0
+		>=media-libs/flac-1.2.1-r1 )
+	fluidsynth? ( media-sound/fluidsynth )
+	http? ( >=net-libs/neon-0.26.4 )
+	gtk? ( x11-libs/gtk+:2
+		   ~media-sound/audacious-${PV}[gtk?] )
+	gtk3? ( x11-libs/gtk+:3
+			media-libs/adplug
+			~media-sound/audacious-${PV}[gtk3?] )
+	qt5? ( dev-qt/qtcore:5
+		   dev-qt/qtgui:5
+		   dev-qt/qtmultimedia:5
+		   dev-qt/qtwidgets:5
+		   media-libs/adplug
+		   ~media-sound/audacious-${PV}[qt5?] )
+	jack? ( >=media-libs/bio2jack-0.4
+		media-sound/jack-audio-connection-kit )
+	lame? ( media-sound/lame )
+	libnotify? ( x11-libs/libnotify )
+	libsamplerate? ( media-libs/libsamplerate )
+	lirc? ( app-misc/lirc )
+	mms? ( >=media-libs/libmms-0.3 )
+	mp3? ( >=media-sound/mpg123-1.12.1 )
+	pulseaudio? ( >=media-sound/pulseaudio-0.9.3 )
+	scrobbler? ( net-misc/curl )
+	sdl? ( media-libs/libsdl[sound] )
+	sid? ( >=media-libs/libsidplayfp-1.0.0 )
+	sndfile? ( >=media-libs/libsndfile-1.0.17-r1 )
+	vorbis? ( >=media-libs/libvorbis-1.2.0
+		  >=media-libs/libogg-1.1.3 )
+	wavpack? ( >=media-sound/wavpack-4.50.1-r1 )"
+
+DEPEND="${RDEPEND}
+	nls? ( dev-util/intltool )
+	virtual/pkgconfig"
+
+mp3_warning() {
+	if ! use mp3 ; then
+		ewarn "MP3 support is optional, you may want to enable the mp3 USE-flag"
+	fi
+}
+
+src_unpack() {
+	default
+	if use gtk3 ; then
+		mv "${MY_P}-gtk3" "${MY_P}"
+	fi
+}
+
+src_prepare() {
+	has_version "<dev-libs/glib-2.32" && \
+		cd "${S}"/src/mpris2 && \
+		gdbus-codegen --interface-prefix org.mpris. \
+			--c-namespace Mpris --generate-c-code object-core mpris2.xml && \
+		gdbus-codegen --interface-prefix org.mpris. \
+			--c-namespace Mpris \
+			--generate-c-code object-player mpris2-player.xml && \
+		cd "${S}"
+}
+
+src_configure() {
+	mp3_warning
+	if use qt5 ;then
+		notify="--disable-notify"
+	elif use libnotify ;then
+		notify="--enable-notify"
+	fi
+
+	if use gtk ;then
+		gtk="--enable-gtk"
+	elif use gtk3 ;then
+		gtk="--enable-gtk"
+	else
+		gtk="--disable-gtk"
+	fi
+
+	if use ffmpeg && has_version media-video/ffmpeg ; then
+		ffmpeg="--with-ffmpeg=ffmpeg"
+	elif use ffmpeg && has_version media-video/libav ; then
+		ffmpeg="--with-ffmpeg=libav"
+	else
+		ffmpeg="--with-ffmpeg=none"
+	fi
+
+	econf \
+		${ffmpeg} \
+		${gtk} \
+		${notify} \
+		--enable-modplug \
+		--enable-mpris2 \
+		--disable-soxr \
+		--disable-oss4 \
+		$(use_enable aac) \
+		$(use_enable alsa) \
+		$(use_enable aosd) \
+		$(use_enable bs2b) \
+		$(use_enable cdda cdaudio) \
+		$(use_enable cue) \
+		$(use_enable flac) \
+		$(use_enable fluidsynth amidiplug) \
+		$(use_enable flac filewriter) \
+		$(use_enable http neon) \
+		$(use_enable jack) \
+		$(use_enable gnome gnomeshortcuts) \
+		$(use_enable lame filewriter_mp3) \
+		$(use_enable libsamplerate resample) \
+		$(use_enable lirc) \
+		$(use_enable mms) \
+		$(use_enable mp3 mpg123) \
+		$(use_enable nls) \
+		$(use_enable pulseaudio pulse) \
+		$(use_enable qt5 qt) \
+		$(use_enable scrobbler scrobbler2) \
+		$(use_enable sdl sdlout) \
+		$(use_enable sid) \
+		$(use_enable sndfile) \
+		$(use_enable vorbis) \
+		$(use_enable wavpack)
+}
diff --git a/media-plugins/audacious-plugins/metadata.xml b/media-plugins/audacious-plugins/metadata.xml
index e5ba67c697db..f9c194a447f6 100644
--- a/media-plugins/audacious-plugins/metadata.xml
+++ b/media-plugins/audacious-plugins/metadata.xml
@@ -12,6 +12,7 @@
 <use>
 	<flag name="adplug">Build with AdPlug (Adlib sound card emulation)
 		support</flag>
+	<flag name="aosd">Enable support for Audacious OSD</flag>
 	<flag name="bs2b">Enable Bauer Bauer stereophonic-to-binaural
 		headphone filter</flag>
 	<flag name="cue">Support CUE sheets using the libcue library</flag>