media-libs/gstreamer: Bump to 1.20.0

Gstreamer 1.20.0 version bump, includes
- all existing 1.18.4 plugins except for two dropped upstream
  (gst-plugins-libmms and gst-plugins-ofa)
- libnice-0.1.18 version bump required by gst-plugins-webrtc in 1.20.0
- required multilib change for libldac for new plugin gst-plugins-ldac
- required multilib change for libopenaptx and libfreeaptx for new plugin
  gst-plugins-openaptx

As discussed, this change adds a LICENSE to each of gstreamer modules which
now require explicit opt-in for (A)GPL plugins for (A)GPL plugins we will not
perform explicit license acceptance for affected gstreamer plugin, instead we
will rely on a user accepting the license of dependency:
- gstreamer change added explicit opt-in https://gitlab.freedesktop.org/gstreamer/gstreamer/-/merge_requests/1084
- I looked at affected gstreamer plugins and looks like all are correctly
  license-compatible according to compatibility matrix https://www.gnu.org/licenses/gpl-faq.html#AllCompatibility
- if a user is not willing to accept the license of corresponding (A)GPL
  dependency, such dependency will not be available and affected gstreamer
  plugin will not be built
- Upstream gstreamer team will look into updating/fixing plugin license display
  available via gst-inspect-1.0 <plugin name> | grep License as currently it is
  just "GPL" which is not specific enough (should be GPL-2, GPL-2+, GPL-3 etc.)

Signed-off-by: Igor V. Kovalenko <igor.v.kovalenko@gmail.com>
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 102 insertions, 0 deletions

diff --git a/media-plugins/gst-plugins-vaapi/Manifest b/media-plugins/gst-plugins-vaapi/Manifest
index 76bd931731f5..d59da4626011 100644
--- a/media-plugins/gst-plugins-vaapi/Manifest
+++ b/media-plugins/gst-plugins-vaapi/Manifest
@@ -1,2 +1,3 @@
 DIST gstreamer-vaapi-1.16.3.tar.xz 1103784 BLAKE2B 89b4f42a9d04f4a03f171f2d3db81a2122ae64147039053dc508bc70f346c976c42ee60455785c3d35762561fa421af13b8e04dae6bca6d64eacad4ed218a281 SHA512 043a53e9e8c5d66cf955c8bc60236846a4a51793bf467d835c0992f490f4e03f0a7c3430c95641a9c659b0f59ae2f99c48bc54985729b5703fa1ecbc062175a0
 DIST gstreamer-vaapi-1.18.4.tar.xz 783132 BLAKE2B 4ab7910dfc7dddc47dd538ed71a09f54ac217906ecfa3c93c10bfc63d5bab1825ada4c2e6076df35e1a8a4c6f20767fa8e43ea4197363a643d010a93026495a0 SHA512 355f0528929d459c8d0f009e7c8b75718ae175b648abfa1a65ed4a8b90e78a18d202b6a2fde2c5cc027a3321afc5adb90295c4f2635d68ebcedc045ac5f5664f
+DIST gstreamer-vaapi-1.20.0.tar.xz 786436 BLAKE2B 0eb3aabe1bd5faa05d7887df6e8b4bd2166f1a361dc6731848ac7b74ede0164d10d6e97439c959447488339843f12653cc6ad384427bf5ae5f4150b297b270fd SHA512 1e26c67f446d88e4bb0a0188b279d2841006b0c46afcd5bc6bccd8c70bcaf5b829b78b8d3d91788446eea03581e5a5f4656e1b35af58ab384ae8b945040d5d6a
diff --git a/media-plugins/gst-plugins-vaapi/gst-plugins-vaapi-1.20.0.ebuild b/media-plugins/gst-plugins-vaapi/gst-plugins-vaapi-1.20.0.ebuild
new file mode 100644
index 000000000000..94682d10393e
--- /dev/null
+++ b/media-plugins/gst-plugins-vaapi/gst-plugins-vaapi-1.20.0.ebuild
@@ -0,0 +1,101 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit gstreamer-meson python-any-r1
+
+MY_PN="gstreamer-vaapi"
+DESCRIPTION="Hardware accelerated video decoding through VA-API plugin for GStreamer"
+HOMEPAGE="https://gitlab.freedesktop.org/gstreamer/gstreamer-vaapi"
+SRC_URI="https://gstreamer.freedesktop.org/src/${MY_PN}/${MY_PN}-${PV}.tar.xz"
+
+LICENSE="LGPL-2.1+"
+SLOT="1.0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="+drm +egl gles2 +opengl wayland +X" # Keep default enabled IUSE in sync with gst-plugins-base and libva
+
+# gst-vaapi configure is based around GL platform mainly, unlike gst-plugins-bad that goes by GL API mainly; for less surprises,
+# we design gst-vaapi ebuild in terms of GL API as main choice as well, meaning that USE opengl and/or gles2 is required to
+# enable opengl support at all and choices get chained from there.
+# One or multiple video output are required: drm, x11, glx, egl and/or wayland;
+# but GL API is our main trigger, thus USE=egl should be ineffective if neither gles2 or opengl is enabled;
+# So "|| ( drm egl opengl wayland X )" would be wrong, because egl isn't built with USE="egl -opengl -gles2", ending up with no video outputs.
+# As we ensure at least one working GL output with other REQUIRED_USE, we can put gles2/opengl in REQUIRED_USE instead of egl, solving the issue.
+# gles2 API only supported windowing system (on linux) is EGL, so require it
+# opengl API only supported windowing systems (on linux) are EGL and GLX, so require one of them (glx is enabled with USE="opengl X")
+REQUIRED_USE="
+	|| ( drm gles2 opengl wayland X )
+	gles2? ( egl )
+	opengl? ( || ( egl X ) )
+"
+
+# glx doesn't require libva-glx (libva[opengl]) afaics, only by tests/test-display.c
+# USE flag behavior:
+# 'drm' enables vaapi drm support
+# 'egl' enables EGL platform support (but only if also 'opengl||gles2')
+# - 'egl' is exposed as a USE flag mainly to get EGL support instead of or in addition to GLX support with desktop GL while keeping it optional for pure GLX cases;
+#   it's always required with USE=gles2, thus USE="gles2 opengl X" will require and build desktop GL EGL platform support as well on top of GLX, which doesn't add extra deps at that point.
+# 'gles2' enables GLESv2 or GLESv3 based GL API support
+# 'opengl' enables desktop OpenGL based GL API support
+# 'wayland' enables non-GL Wayland support; wayland EGL support when combined with 'egl' (but only if also 'opengl||gles2')
+# 'X' enables non-GL X support; GLX support when combined with 'opengl'
+# gst-plugins-bad still needed for codecparsers (GL libraries moved to -base); checked for 1.14 (recheck for 1.16)
+GST_REQ="${PV}"
+GL_DEPS="
+	>=media-libs/gst-plugins-base-${GST_REQ}:${SLOT}[egl?,gles2?,opengl?,wayland?,X?]
+	media-libs/mesa[gles2?,egl(+)?,X?,${MULTILIB_USEDEP}]
+"
+RDEPEND="
+	>=dev-libs/glib-2.40:2[${MULTILIB_USEDEP}]
+	>=media-libs/gst-plugins-base-${GST_REQ}:${SLOT}[${MULTILIB_USEDEP}]
+	>=media-libs/gst-plugins-bad-${GST_REQ}:${SLOT}[${MULTILIB_USEDEP}]
+	>=x11-libs/libva-1.4.0:=[drm?,wayland?,X?,${MULTILIB_USEDEP}]
+	drm? (
+		>=virtual/libudev-208:=[${MULTILIB_USEDEP}]
+		>=x11-libs/libdrm-2.4.46[${MULTILIB_USEDEP}]
+	)
+	gles2? ( ${GL_DEPS} )
+	opengl? ( ${GL_DEPS} )
+	wayland? ( >=dev-libs/wayland-1.11.0[${MULTILIB_USEDEP}] )
+	X? (
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXrandr-1.4.2[${MULTILIB_USEDEP}]
+		x11-libs/libXrender[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.12
+"
+BDEPEND="${PYTHON_DEPS}"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+# FIXME: "Failed to create vaapipostproc element"
+RESTRICT="test"
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Dwith_encoders=yes
+		-Dwith_drm=$(usex drm yes no)
+		-Dwith_x11=$(usex X yes no)
+		-Dwith_wayland=$(usex wayland yes no)
+	)
+
+	if use opengl || use gles2; then
+		emesonargs+=( -Dwith_egl=$(usex egl yes no) )
+	else
+		emesonargs+=( -Dwith_egl=no )
+	fi
+
+	if use opengl && use X; then
+		emesonargs+=( -Dwith_glx=yes )
+	else
+		emesonargs+=( -Dwith_glx=no )
+	fi
+
+	# Workaround EGL/eglplatform.h being built with X11 present
+	use X || export CFLAGS="${CFLAGS} -DEGL_NO_X11"
+
+	gstreamer_multilib_src_configure
+}