media-sound/audacious: bump to version 4.1

Drop 3.x as it is require GTK+:2

Closes: https://bugs.gentoo.org/775989
Closes: https://bugs.gentoo.org/797835
Bug: https://bugs.gentoo.org/711292
Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Marco Scardovi <marco@scardovi.com>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

1 files changed, 70 insertions, 0 deletions

diff --git a/media-sound/audacious/audacious-4.1.ebuild b/media-sound/audacious/audacious-4.1.ebuild
new file mode 100644
index 000000000000..2f78f555ee74
--- /dev/null
+++ b/media-sound/audacious/audacious-4.1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_P="${P/_/-}"
+
+inherit xdg
+
+DESCRIPTION="Lightweight and versatile audio player"
+HOMEPAGE="https://audacious-media-player.org/"
+SRC_URI="https://distfiles.audacious-media-player.org/${MY_P}.tar.bz2"
+SRC_URI+=" mirror://gentoo/gentoo_ice-xmms-0.2.tar.bz2"
+
+KEYWORDS="~amd64 ~x86"
+LICENSE="BSD-2"
+SLOT="0"
+IUSE="nls"
+
+BDEPEND="
+	virtual/pkgconfig
+	nls? ( dev-util/intltool )
+"
+DEPEND="
+	>=dev-libs/dbus-glib-0.60
+	>=dev-libs/glib-2.28
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	>=x11-libs/cairo-1.2.6
+	>=x11-libs/pango-1.8.0
+	virtual/freedesktop-icon-theme
+"
+RDEPEND="${DEPEND}"
+PDEPEND="~media-plugins/audacious-plugins-${PV}"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	default
+	if ! use nls; then
+		sed -e "/SUBDIRS/s/ po//" -i Makefile || die "failed to sed" # bug #512698
+	fi
+}
+
+src_configure() {
+	# D-Bus is a mandatory dependency, remote control,
+	# session management and some plugins depend on this.
+	# Building without D-Bus is *unsupported* and a USE-flag
+	# will not be added due to the bug reports that will result.
+	# Bugs #197894, #199069, #207330, #208606
+	local myeconfargs=(
+		--disable-valgrind
+		--disable-gtk
+		--enable-dbus
+		--enable-qt
+		$(use_enable nls)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	# Gentoo_ice skin installation; bug #109772
+	insinto /usr/share/audacious/Skins/gentoo_ice
+	doins -r "${WORKDIR}"/gentoo_ice/.
+	docinto gentoo_ice
+	dodoc "${WORKDIR}"/README
+}