media-sound/elisa: 21.08.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 64 insertions, 0 deletions

diff --git a/media-sound/elisa/Manifest b/media-sound/elisa/Manifest
index 011b6c3d7090..39ce6693cb6a 100644
--- a/media-sound/elisa/Manifest
+++ b/media-sound/elisa/Manifest
@@ -1 +1,2 @@
 DIST elisa-21.04.3.tar.xz 1725896 BLAKE2B 4937403cb1e58c23979ec5525232f227a92f4cfded11127af2cbf62b1f0a72163f39f1a02bec5e9d5acb9c78659f66bb3519a7ab322aaf3a5be7f855975cf365 SHA512 12a83267332f3d36d4906cd9dbc6c46558cd5a3efbf67ccdcfc53156e4e6b3cf334cd05033bc299105ce72df3625852ba8b9dc1438c0b50b7e29798796699ecc
+DIST elisa-21.08.0.tar.xz 1738180 BLAKE2B 60d4fd99a372c1527d706eed9ab477533028994693eecce6c951a309e05399d75f4a2d704d22bddf456422327d19d19a0983486a0ab31d28fea77d35856d4775 SHA512 cde8d64306a8c85d8b7c9853ddc5f12b06ae3ab902d7e8eb090f7a6125238998a965451bffa17148ea54bdf0a002bd0349b4febc8830b308c75ef95bd5a37c28
diff --git a/media-sound/elisa/elisa-21.08.0.ebuild b/media-sound/elisa/elisa-21.08.0.ebuild
new file mode 100644
index 000000000000..a1036dddb937
--- /dev/null
+++ b/media-sound/elisa/elisa-21.08.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="optional"
+ECM_TEST="forceoptional"
+KDE_GEAR="true"
+KFMIN=5.84.0
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="Simple music player by KDE"
+HOMEPAGE="https://elisa.kde.org/ https://apps.kde.org/elisa/"
+
+LICENSE="LGPL-3+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="mpris semantic-desktop +vlc"
+
+RESTRICT+=" test"
+
+BDEPEND="sys-devel/gettext"
+DEPEND="
+	>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtmultimedia-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/kfilemetadata-${KFMIN}:5[taglib]
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	mpris? (
+		>=dev-qt/qtdbus-${QTMIN}:5
+		>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	)
+	semantic-desktop? ( >=kde-frameworks/baloo-${KFMIN}:5 )
+	vlc? ( media-video/vlc:= )
+	!vlc? ( >=dev-qt/qtmultimedia-${QTMIN}:5[gstreamer] )
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtgraphicaleffects-${QTMIN}:5
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package mpris KF5DBusAddons)
+		$(cmake_use_find_package semantic-desktop KF5Baloo)
+		$(cmake_use_find_package vlc LIBVLC)
+	)
+
+	ecm_src_configure
+}