media-sound/exile: bump to 4.1.0_alpha1 + added live + dropped py2

based on updated ebuild provided by Wicher Minnaard <wicher@gavagai.eu>

Closes: https://bugs.gentoo.org/708966
Package-Manager: Portage-3.0.2, Repoman-2.3.23
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

4 files changed, 120 insertions, 27 deletions

diff --git a/media-sound/exaile/Manifest b/media-sound/exaile/Manifest
index 0b01eca38e44..b91cb78d9a0d 100644
--- a/media-sound/exaile/Manifest
+++ b/media-sound/exaile/Manifest
@@ -1 +1 @@
-DIST exaile-4.0.0.tar.gz 3635774 BLAKE2B 91a5a0a4b8f3c55ec1c8f6487f30bbc8193b1e8b861bbc4bf3cba18dcef91c8a58c937e7a581378eec9da518565826c35e55b7ab157b7ee4634d36cd71a85c4e SHA512 50ab8ec7a65dc431f2bc71a302d21e59ac3d5939b89a90ec161527e1d5c0b80b8c396f8f323b2959e0b807f577e021863fe423bf26a8f7165a6dd112afca6e45
+DIST exaile-4.1.0alpha1.tar.gz 3605803 BLAKE2B ea4862581aa4d95c1944967e1d30979284538353e7d95ef345e6dddf1702be98e4c7c21918bf9a8cb277f339c812fd6671d84e695d6e5b179a2f65358e0e75f0 SHA512 56e73f7cc4d250fbc30870170b50f65f0f99d27e97a8f28dd043af9eb93c919a8de3ed790cbd6c441133232afb3c405fa830cb62c8c33bb0a6e4d97b79d5b54d
diff --git a/media-sound/exaile/exaile-4.0.0-r1.ebuild b/media-sound/exaile/exaile-4.1.0_alpha1.ebuild
index 0b906b58ea75..ea8a80d4a9e1 100644
--- a/media-sound/exaile/exaile-4.0.0-r1.ebuild
+++ b/media-sound/exaile/exaile-4.1.0_alpha1.ebuild
@@ -3,33 +3,37 @@
 
 EAPI=7
 
-PYTHON_COMPAT=( python2_7 )
-PYTHON_REQ_USE="sqlite"
-inherit python-single-r1 xdg-utils
+PYTHON_COMPAT=( python3_{6,7,8} )
+inherit python-single-r1 xdg
 
-if [[ ${PV} = *9999* ]]; then
+if [[ ${PV} == "9999" ]]; then
 	inherit git-r3
 	EGIT_REPO_URI="https://github.com/exaile/exaile.git"
 else
-	SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV/_/-}/${PN}-${PV/_/}.tar.gz"
-	KEYWORDS="amd64 x86"
-	S="${WORKDIR}/${PN}-${PV/_/}"
+	SRC_URI="https://github.com/${PN}/${PN}/archive/${PV/_/-}/${PN}-${PV/_/}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${PN}-${PV/_/-}"
 fi
 
 DESCRIPTION="GTK+ based media player aiming to be similar to Amarok"
 HOMEPAGE="https://www.exaile.org/"
-
 LICENSE="GPL-2 GPL-3"
 SLOT="0"
-IUSE="cddb libnotify nls scrobbler"
+# IUSE+=cddb if have dev-python/cddb-py
+IUSE="libnotify nls scrobbler"
 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
 
+BDEPEND="
+	nls? (
+		dev-util/intltool
+		sys-devel/gettext
+	)
+"
 RDEPEND="${PYTHON_DEPS}
 	>=media-libs/gst-plugins-base-1.6:1.0
 	>=media-libs/gst-plugins-good-1.4:1.0
 	media-plugins/gst-plugins-meta:1.0
 	>=x11-libs/gtk+-3.10:3[introspection]
-	cddb? ( dev-python/cddb-py )
 	libnotify? ( >=x11-libs/libnotify-0.7[introspection] )
 	$(python_gen_cond_dep '
 		dev-python/bsddb3[${PYTHON_MULTI_USEDEP}]
@@ -41,15 +45,13 @@ RDEPEND="${PYTHON_DEPS}
 		scrobbler? ( dev-python/pylast[${PYTHON_MULTI_USEDEP}] )
 	')
 "
-BDEPEND="
-	nls? (
-		dev-util/intltool
-		sys-devel/gettext
-	)
-"
 
 RESTRICT="test" #315589
 
+PATCHES=(
+	"${FILESDIR}/${P}-metainfo.patch"
+)
+
 pkg_setup() {
 	python-single-r1_pkg_setup
 }
@@ -68,13 +70,3 @@ src_install() {
 	python_optimize "${D}/usr/$(get_libdir)/${PN}"
 	python_optimize "${D}/usr/share/${PN}"
 }
-
-pkg_postinst() {
-	xdg_desktop_database_update
-	xdg_mimeinfo_database_update
-}
-
-pkg_postrm() {
-	xdg_desktop_database_update
-	xdg_mimeinfo_database_update
-}
diff --git a/media-sound/exaile/exaile-9999.ebuild b/media-sound/exaile/exaile-9999.ebuild
new file mode 100644
index 000000000000..48f583a4ba0a
--- /dev/null
+++ b/media-sound/exaile/exaile-9999.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+inherit python-single-r1 xdg
+
+if [[ ${PV} == "9999" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/exaile/exaile.git"
+else
+	SRC_URI="https://github.com/${PN}/${PN}/archive/${PV/_/-}/${PN}-${PV/_/}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${PN}-${PV/_/-}"
+fi
+
+DESCRIPTION="GTK+ based media player aiming to be similar to Amarok"
+HOMEPAGE="https://www.exaile.org/"
+LICENSE="GPL-2 GPL-3"
+SLOT="0"
+# IUSE+=cddb if have dev-python/cddb-py
+IUSE="libnotify nls scrobbler"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+BDEPEND="
+	nls? (
+		dev-util/intltool
+		sys-devel/gettext
+	)
+"
+RDEPEND="${PYTHON_DEPS}
+	>=media-libs/gst-plugins-base-1.6:1.0
+	>=media-libs/gst-plugins-good-1.4:1.0
+	media-plugins/gst-plugins-meta:1.0
+	>=x11-libs/gtk+-3.10:3[introspection]
+	libnotify? ( >=x11-libs/libnotify-0.7[introspection] )
+	$(python_gen_cond_dep '
+		dev-python/bsddb3[${PYTHON_MULTI_USEDEP}]
+		dev-python/dbus-python[${PYTHON_MULTI_USEDEP}]
+		dev-python/gst-python:1.0[${PYTHON_MULTI_USEDEP}]
+		dev-python/pycairo[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/pygobject-3.13.2:3[${PYTHON_MULTI_USEDEP}]
+		>=media-libs/mutagen-1.10[${PYTHON_MULTI_USEDEP}]
+		scrobbler? ( dev-python/pylast[${PYTHON_MULTI_USEDEP}] )
+	')
+"
+
+RESTRICT="test" #315589
+
+PATCHES=(
+	"${FILESDIR}/${PN}-4.1.0_alpha1-metainfo.patch"
+)
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_compile() {
+	use nls && emake locale
+}
+
+src_install() {
+	emake \
+		PREFIX=/usr \
+		LIBINSTALLDIR=/usr/$(get_libdir) \
+		DESTDIR="${D}" \
+		install$(use nls || echo _no_locale)
+
+	python_optimize "${D}/usr/$(get_libdir)/${PN}"
+	python_optimize "${D}/usr/share/${PN}"
+}
diff --git a/media-sound/exaile/files/exaile-4.1.0_alpha1-metainfo.patch b/media-sound/exaile/files/exaile-4.1.0_alpha1-metainfo.patch
new file mode 100644
index 000000000000..11e80706bd8e
--- /dev/null
+++ b/media-sound/exaile/files/exaile-4.1.0_alpha1-metainfo.patch
@@ -0,0 +1,29 @@
+--- exaile-4.1.0-alpha1_orig/Makefile	2020-03-09 01:54:13.000000000 +0100

++++ exaile-4.1.0-alpha1/Makefile	2020-08-03 10:14:23.498153577 +0200

+@@ -81,7 +81,7 @@

+ 	install -d -m 755 $(EXAILESHAREDIR)/data/ui/preferences/widgets

+ 	install -d -m 755 $(EXAILESHAREDIR)/data/ui/widgets

+ 	install -d -m 755 $(DESTDIR)$(DATADIR)/pixmaps

+-	install -d -m 755 $(DESTDIR)$(DATADIR)/appdata

++	install -d -m 755 $(DESTDIR)$(DATADIR)/metainfo

+ 	install -d -m 755 $(DESTDIR)$(DATADIR)/applications

+ 	install -d -m 755 $(DESTDIR)$(DATADIR)/dbus-1/services

+ 	install -d -m 755 $(EXAILEMANDIR)/man1

+@@ -96,7 +96,7 @@

+ 	rm -rf $(EXAILECONFDIR)

+ 	rm -f $(DESTDIR)$(DATADIR)/applications/exaile.desktop

+ 	rm -f $(DESTDIR)$(DATADIR)/pixmaps/exaile.png

+-	rm -f $(DESTDIR)$(DATADIR)/appdata/exaile.appdata.xml

++	rm -f $(DESTDIR)$(DATADIR)/metainfo/exaile.metainfo.xml

+ 	rm -f $(DESTDIR)$(DATADIR)/dbus-1/services/org.exaile.Exaile.service

+ 	rm -f $(EXAILEMANDIR)/man1/exaile.1.gz

+ 	rm -f $(DESTDIR)$(BASHCOMPDIR)/exaile

+@@ -154,7 +154,7 @@

+ 	install -m 644 data/exaile.desktop \

+ 		$(DESTDIR)$(DATADIR)/applications/

+ 	install -m 644 data/exaile.appdata.xml \

+-		$(DESTDIR)$(DATADIR)/appdata/

++		$(DESTDIR)$(DATADIR)/metainfo/exaile.metainfo.xml

+ 	-install -m 644 build/exaile.1.gz $(EXAILEMANDIR)/man1/

+ 	-install -m 644 build/exaile.bash-completion $(DESTDIR)$(BASHCOMPDIR)/exaile

+ 	-install -m 644 build/exaile.fish-completion $(DESTDIR)$(FISHCOMPDIR)/exaile.fish