media-sound/mp3diags: new package

Package-Manager: Portage-2.3.66, Repoman-2.3.16
Signed-off-by: Michael Palimaka <kensington@gentoo.org>

1 files changed, 56 insertions, 0 deletions

diff --git a/media-sound/mp3diags/mp3diags-1.5.01.ebuild b/media-sound/mp3diags/mp3diags-1.5.01.ebuild
new file mode 100644
index 000000000000..2d96e59d1931
--- /dev/null
+++ b/media-sound/mp3diags/mp3diags-1.5.01.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop qmake-utils xdg-utils
+
+MY_PN=MP3Diags-unstable
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Qt-based MP3 diagnosis and repair tool"
+HOMEPAGE="http://mp3diags.sourceforge.net"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+
+LICENSE="LGPL-3 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+
+DEPEND="
+	dev-libs/boost:=[threads]
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	sys-libs/zlib
+"
+RDEPEND="${DEPEND}
+	dev-qt/qtsvg:5
+"
+
+S=${WORKDIR}/${MY_P}
+
+src_configure() {
+	eqmake5 ${PN}.pro
+}
+
+src_install() {
+	dobin bin/${MY_PN}
+	dodoc changelog.txt
+
+	local size
+	for size in 16 22 24 32 36 40 48; do
+		insinto /usr/share/icons/hicolor/${size}x${size}/apps
+		newins desktop/${MY_PN}${size}.png ${MY_PN}.png
+	done
+	domenu desktop/${MY_PN}.desktop
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}