net-dialup/accel-ppp: version bump

- add new snapshot
- add support for dev-libs/libtomcrypt
- sync live ebuild

Package-Manager: Portage-3.0.18, Repoman-3.0.2
Signed-off-by: Sergey Popov <pinkbyte@gentoo.org>

4 files changed, 123 insertions, 7 deletions

diff --git a/net-dialup/accel-ppp/Manifest b/net-dialup/accel-ppp/Manifest
index 03fa3a5ef155..070c8e705acd 100644
--- a/net-dialup/accel-ppp/Manifest
+++ b/net-dialup/accel-ppp/Manifest
@@ -1 +1,2 @@
 DIST accel-ppp-1.12.0_p20200913.tar.bz2 1661195 BLAKE2B 6ffdb140486e98c19c981999873f94e767682bec1a2bea1f2feb7bed6ce9d8b15a824605da0b60897501773f4ece9d71612385dd1eff61483fff5daadad9713d SHA512 ecf325774507a8ddb1c6fe3c90aa2e25c72d006e9d96eabf66c7f1b67cfa70fc1073cf120c195d0823ad2532fa3504f6ab482d1842eb8b3e3dbafdb8b16a2ac6
+DIST accel-ppp-1.12.0_p20210430.tar.bz2 1662172 BLAKE2B 7c9da06ca704d63afb16bc8d2bc64541e25d31a062a948c3014f340684a38c7ba55d15eba3458ced90b088788228f97553105fd5d0aebbb1e61fb1b1075ae521 SHA512 de690a44ebaad31c63ec604c306e3d5bc63bd02ea2c17a435c2166ddcc8a3c06b86d72d6ebd88d906093583345962569493231e1657f222d4e66d93bf1d0ca41
diff --git a/net-dialup/accel-ppp/accel-ppp-1.12.0_p20210430.ebuild b/net-dialup/accel-ppp/accel-ppp-1.12.0_p20210430.ebuild
new file mode 100644
index 000000000000..e36b6e068503
--- /dev/null
+++ b/net-dialup/accel-ppp/accel-ppp-1.12.0_p20210430.ebuild
@@ -0,0 +1,113 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-1 )
+
+inherit cmake flag-o-matic linux-info linux-mod lua-single
+
+DESCRIPTION="High performance PPTP, PPPoE and L2TP server"
+HOMEPAGE="https://sourceforge.net/projects/accel-ppp/"
+SRC_URI="https://dev.gentoo.org/~pinkbyte/distfiles/snapshots/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug doc ipoe libtomcrypt lua postgres radius shaper snmp valgrind"
+
+RDEPEND="!libtomcrypt? ( dev-libs/openssl:0= )
+	libtomcrypt? ( dev-libs/libtomcrypt:0= )
+	lua? ( ${LUA_DEPS} )
+	postgres? ( dev-db/postgresql:* )
+	snmp? ( net-analyzer/net-snmp )
+	dev-libs/libpcre"
+DEPEND="${RDEPEND}
+	valgrind? ( dev-util/valgrind )"
+PDEPEND="net-dialup/ppp-scripts"
+
+DOCS=( README )
+
+CONFIG_CHECK="~L2TP ~PPPOE ~PPTP"
+
+REQUIRED_USE="lua? ( ${LUA_REQUIRED_USE} )
+	valgrind? ( debug )"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.11.1-socklen.patch"
+)
+
+S="${WORKDIR}"
+
+pkg_setup() {
+	if use ipoe; then
+		linux-mod_pkg_setup
+		set_arch_to_kernel
+	else
+		linux-info_pkg_setup
+	fi
+	use lua && lua-single_pkg_setup
+}
+
+src_prepare() {
+	sed -i  -e "/mkdir/d" \
+		-e "s: RENAME accel-ppp.conf.dist::" accel-pppd/CMakeLists.txt || die 'sed on accel-pppd/CMakeLists.txt failed'
+
+	# Do not install kernel modules like that - breaks sandbox!
+	sed -i -e '/modules_install/d' \
+		drivers/ipoe/CMakeLists.txt \
+		drivers/vlan_mon/CMakeLists.txt || die
+
+	# Fix version
+	sed -i -e "s/1.11/${PV}/" drivers/ipoe/ipoe.c || die
+	sed -i -e "s/1.11/${PV}/" drivers/vlan_mon/vlan_mon.c || die
+
+	# Bug #549918
+	append-ldflags -Wl,-z,lazy
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local libdir="$(get_libdir)"
+	local mycmakeargs=(
+		-DLIB_SUFFIX="${libdir#lib}"
+		-DBUILD_IPOE_DRIVER="$(usex ipoe)"
+		-DBUILD_PPTP_DRIVER=no
+		-DBUILD_VLAN_MON_DRIVER="$(usex ipoe)"
+		-DCRYPTO="$(usex libtomcrypt TOMCRYPT OPENSSL)"
+		-DLOG_PGSQL="$(usex postgres)"
+		-DLUA="$(usex lua TRUE FALSE)"
+		-DMEMDEBUG="$(usex debug)"
+		-DNETSNMP="$(usex snmp)"
+		-DRADIUS="$(usex radius)"
+		-DSHAPER="$(usex shaper)"
+		$(use debug && echo "-DVALGRIND=$(usex valgrind)")
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+}
+
+src_install() {
+	if use ipoe; then
+		local MODULE_NAMES="ipoe(accel-ppp:${BUILD_DIR}/drivers/ipoe/driver) vlan_mon(accel-ppp:${BUILD_DIR}/drivers/vlan_mon/driver)"
+		linux-mod_src_install
+	fi
+
+	cmake_src_install
+
+	use doc && dodoc -r rfc
+
+	if use snmp; then
+		insinto /usr/share/snmp/mibs
+		doins accel-pppd/extra/net-snmp/ACCEL-PPP-MIB.txt
+	fi
+
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}d
+	newconfd "${FILESDIR}"/${PN}.confd ${PN}d
+
+	keepdir /var/log/accel-ppp
+}
diff --git a/net-dialup/accel-ppp/accel-ppp-9999.ebuild b/net-dialup/accel-ppp/accel-ppp-9999.ebuild
index fd43b44ecd20..f517be83f27b 100644
--- a/net-dialup/accel-ppp/accel-ppp-9999.ebuild
+++ b/net-dialup/accel-ppp/accel-ppp-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -15,13 +15,14 @@ SRC_URI=""
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS=""
-IUSE="debug doc ipoe lua postgres radius shaper snmp valgrind"
+IUSE="debug doc ipoe libtomcrypt lua postgres radius shaper snmp valgrind"
 
-RDEPEND="lua? ( ${LUA_DEPS} )
+RDEPEND="!libtomcrypt? ( dev-libs/openssl:0= )
+	libtomcrypt? ( dev-libs/libtomcrypt:0= )
+	lua? ( ${LUA_DEPS} )
 	postgres? ( dev-db/postgresql:* )
 	snmp? ( net-analyzer/net-snmp )
-	dev-libs/libpcre
-	dev-libs/openssl:0="
+	dev-libs/libpcre"
 DEPEND="${RDEPEND}
 	valgrind? ( dev-util/valgrind )"
 PDEPEND="net-dialup/ppp-scripts"
@@ -60,13 +61,12 @@ src_prepare() {
 
 src_configure() {
 	local libdir="$(get_libdir)"
-	# There must be also dev-libs/tomcrypt (TOMCRYPT) as crypto alternative to OpenSSL
 	local mycmakeargs=(
 		-DLIB_SUFFIX="${libdir#lib}"
 		-DBUILD_IPOE_DRIVER="$(usex ipoe)"
 		-DBUILD_PPTP_DRIVER=no
 		-DBUILD_VLAN_MON_DRIVER="$(usex ipoe)"
-		-DCRYPTO=OPENSSL
+		-DCRYPTO="$(usex libtomcrypt TOMCRYPT OPENSSL)"
 		-DLOG_PGSQL="$(usex postgres)"
 		-DLUA="$(usex lua TRUE FALSE)"
 		-DMEMDEBUG="$(usex debug)"
diff --git a/net-dialup/accel-ppp/metadata.xml b/net-dialup/accel-ppp/metadata.xml
index 138dfdc41815..20e35c390d9b 100644
--- a/net-dialup/accel-ppp/metadata.xml
+++ b/net-dialup/accel-ppp/metadata.xml
@@ -7,10 +7,12 @@
 	</maintainer>
 	<use>
 		<flag name="ipoe">Build IPoE kernel module</flag>
+		<flag name="libtomcrypt">Support crypto algorithms through <pkg>dev-libs/libtomcrypt</pkg> instead of <pkg>dev-libs/openssl</pkg></flag>
 		<flag name="shaper">Support for traffic shaping</flag>
 		<flag name="valgrind">Compile in valgrind hints</flag>
 	</use>
 	<upstream>
+		<remote-id type="github">xebd/accel-ppp</remote-id>
 		<remote-id type="sourceforge">accel-ppp</remote-id>
 	</upstream>
 </pkgmetadata>