net-dns/pdns-recursor: add 4.7.4

Signed-off-by: Sven Wegener <swegener@gentoo.org>

2 files changed, 89 insertions, 0 deletions

diff --git a/net-dns/pdns-recursor/Manifest b/net-dns/pdns-recursor/Manifest
index b8f16ee04550..b97b16ec6a86 100644
--- a/net-dns/pdns-recursor/Manifest
+++ b/net-dns/pdns-recursor/Manifest
@@ -1,2 +1,3 @@
 DIST pdns-recursor-4.7.2.tar.bz2 1580602 BLAKE2B 2d32d553629f665f9060e58f994a0256adc936f6fdb32ecd236ba202731342fe7e17db6678649292b4d1dd97e8579851e38fe41fd4f122dbf3d63f3d71c5de13 SHA512 b80fb1f403d5b81cf7500f6fce64914ab858b7bd7f617265db9a11ea78786de702563482c5b9daa5c9da1c19a0d02d90fd1f4f14b740d2fd492def7f4b1a7def
 DIST pdns-recursor-4.7.3.tar.bz2 1597064 BLAKE2B e5732c20f18b6711b854a2bcce36705f0f5fbf106e615a646b0a823e0eb4be8ff315f28ebbae77b67935c77255108b92f4ee6515f61019729f5191dfe147ade9 SHA512 e7d9fa32dd53e9b382689e6e735f35b12dbd9f2bb0e8b3031ab58f53a61b5cdc947cb5e857a991768afd1b403bc02d20d434dded5800be450ad45368c9d1dc0e
+DIST pdns-recursor-4.7.4.tar.bz2 1609031 BLAKE2B b051a77f1c734546b26c3bb0030c0e57ee4621b14f0e92d7d294fb80fde599aa813f56a64750e1a00587fee8f05aa9ae1def94f3c3709b103223ed48124b66a7 SHA512 51ecccb557a5a9f3aa28144b60ab75b0fe5534bb2534b0a44662b474a01a0fae61f08b8ca787fc27f22b2a89b721ae66e1a954c4ceb829e66f89f286d5e174a8
diff --git a/net-dns/pdns-recursor/pdns-recursor-4.7.4.ebuild b/net-dns/pdns-recursor/pdns-recursor-4.7.4.ebuild
new file mode 100644
index 000000000000..c8d6a1da1b22
--- /dev/null
+++ b/net-dns/pdns-recursor/pdns-recursor-4.7.4.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..4} luajit )
+
+inherit flag-o-matic lua-single
+
+DESCRIPTION="The PowerDNS Recursor"
+HOMEPAGE="https://www.powerdns.com/"
+SRC_URI="https://downloads.powerdns.com/releases/${P/_/-}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="debug dnstap snmp sodium systemd test"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+DEPEND="${LUA_DEPS}
+	dnstap? ( dev-libs/fstrm )
+	systemd? ( sys-apps/systemd:0= )
+	snmp? ( net-analyzer/net-snmp )
+	sodium? ( dev-libs/libsodium:= )
+	elibc_glibc? (
+		arm? ( >=sys-libs/glibc-2.34 )
+		x86? ( >=sys-libs/glibc-2.34 )
+	)
+	dev-libs/openssl:=
+	dev-libs/boost:=[context]"
+RDEPEND="${DEPEND}
+	!<net-dns/pdns-2.9.20-r1
+	acct-user/pdns
+	acct-group/pdns"
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}"/${P/_/-}
+
+pkg_setup() {
+	lua-single_pkg_setup
+	filter-flags -ftree-vectorize
+	append-lfs-flags
+	append-cppflags -D_TIME_BITS=64
+}
+
+src_configure() {
+	econf \
+		--sysconfdir=/etc/powerdns \
+		--with-nod-cache-dir=/var/lib/powerdns \
+		--with-service-user=pdns \
+		--with-service-group=pdns \
+		--with-lua="${ELUA}" \
+		$(use_enable debug verbose-logging) \
+		$(use_enable systemd) \
+		$(use_enable dnstap dnstap) \
+		$(use_enable test unit-tests) \
+		$(use_with sodium libsodium) \
+		$(use_with snmp net-snmp)
+}
+
+src_install() {
+	default
+
+	mv "${D}"/etc/powerdns/recursor.conf{-dist,}
+
+	# set defaults: setuid=nobody, setgid=nobody
+	sed -i \
+		-e 's/^# set\([ug]\)id=$/set\1id=pdns/' \
+		-e 's/^# quiet=$/quiet=on/' \
+		-e 's/^# chroot=$/chroot=\/var\/lib\/powerdns/' \
+		"${D}"/etc/powerdns/recursor.conf
+
+	newinitd "${FILESDIR}"/pdns-recursor-r2 pdns-recursor
+}
+
+pkg_postinst() {
+	local old
+
+	for old in ${REPLACING_VERSIONS}; do
+		ver_test ${old} -lt 4.0.0-r1 || continue
+
+		ewarn "Starting with 4.0.0-r1 the init script has been renamed from precursor"
+		ewarn "to pdns-recursor, please update your runlevels accordingly."
+
+		break
+	done
+}