net-libs/libpcap: add 1.10.4

Signed-off-by: Sam James <sam@gentoo.org>

3 files changed, 100 insertions, 1 deletions

diff --git a/net-libs/libpcap/Manifest b/net-libs/libpcap/Manifest
index 88e72a145a9d..2eb67bbfa2a5 100644
--- a/net-libs/libpcap/Manifest
+++ b/net-libs/libpcap/Manifest
@@ -4,3 +4,5 @@ DIST libpcap-1.10.2.tar.gz 951063 BLAKE2B f8280c8e12065b4d86e451df8504c834da9c94
 DIST libpcap-1.10.2.tar.gz.sig 442 BLAKE2B c470ff70e58c13dfd1a6d72a00d83883515b9ca63e1561b3acbb75d744b043726df9b8dcb70dfa5ea1c0fa54624a407364d85e83fd3ec4dfd605aa401f5351df SHA512 122bf14c2525a05b2781f6d7bc029d73bcf4584c184220b9f9716def327cc0521ec78d658ad58bdf8a9cd9415ab9ad4d1d24ed1880db25ace6a01a93786bcc5e
 DIST libpcap-1.10.3.tar.gz 951869 BLAKE2B 3614042f7d8cd5a25221f52d2ed09f9f44643cdc0901ff21041ddb7ba85193c667036f7d989c8b59e6e205d630e062da46533110914dd287013a9ff80b31e97f SHA512 57bc07cbc8c326e203ce10ce1eb9f55760fc33320718d8643c65a68949334291877dffcf19af5f61eb9b4eda2d8ffe7bacee38363d2d6536cc85ae81c851684d
 DIST libpcap-1.10.3.tar.gz.sig 442 BLAKE2B 30f0053bc05564fd06aeac751d85eb4838c55c783a0eed450f4de238391c87b8915378f4dc679a14276c9e5e17e9bc74b861241a0a0e86bb22dc2680552f43db SHA512 dc5ae51a96f9dfc570009a5c711a1e4eca012e99d6eb7af3b35c5636199b3273e92a657fdf85688650c093cc9b6c435ba1e9b84100469b2604b8d3125613b4ab
+DIST libpcap-1.10.4.tar.gz 952153 BLAKE2B 05a7eafc1e1817f7844008db89d8fb10cd2525c22f7ee6c9e3d582b14229412f38ccced5e9d80a96dd459ef9eab12eccb5c1dd4978ddc9f66267469212005e4c SHA512 1f6d6ddd07dae7c557054cb246437ecdaf39d579592a5a6bdf1144eea6cb5a779ac4ca647cfed11ec1b0bb18efc63b845444e497070bacefaaed19a5787ae5e1
+DIST libpcap-1.10.4.tar.gz.sig 442 BLAKE2B d0eb5da9a57003848b24d458e50a201d0bb8876a12e63f6627bf9dc1a784e780610cd0c858243cc75a63999b40bc64507b078777ae844ede7c07eef9f4f9e0d5 SHA512 34aa401c2e162d708c61b78b445af2fe4ddc0e57de9124b5cc3a05679ffbc3834088160f83892d827e25c65b33313fe71aa73c2de09935d387252ab315ca5ee1
diff --git a/net-libs/libpcap/libpcap-1.10.4.ebuild b/net-libs/libpcap/libpcap-1.10.4.ebuild
new file mode 100644
index 000000000000..a229dbe01d7e
--- /dev/null
+++ b/net-libs/libpcap/libpcap-1.10.4.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools multilib-minimal
+
+DESCRIPTION="A system-independent library for user-level network packet capture"
+HOMEPAGE="https://www.tcpdump.org/ https://github.com/the-tcpdump-group/libpcap"
+
+if [[ ${PV} == *9999* ]] ; then
+	EGIT_REPO_URI="https://github.com/the-tcpdump-group/libpcap"
+	inherit git-r3
+else
+	VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/tcpdump.asc
+	inherit verify-sig
+
+	SRC_URI="https://www.tcpdump.org/release/${P}.tar.gz"
+	SRC_URI+=" verify-sig? ( https://www.tcpdump.org/release/${P}.tar.gz.sig )"
+
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~x86-solaris"
+fi
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="bluetooth dbus netlink rdma remote static-libs test usb yydebug"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	bluetooth? ( net-wireless/bluez:=[${MULTILIB_USEDEP}] )
+	dbus? ( sys-apps/dbus[${MULTILIB_USEDEP}] )
+	netlink? ( dev-libs/libnl:3[${MULTILIB_USEDEP}] )
+	remote? ( virtual/libcrypt:=[${MULTILIB_USEDEP}] )
+	rdma? ( sys-cluster/rdma-core )
+	usb? ( virtual/libusb:1[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	app-alternatives/yacc
+	sys-devel/flex
+	dbus? ( virtual/pkgconfig )
+"
+
+if [[ ${PV} != *9999* ]] ; then
+	BDEPEND+=" verify-sig? ( sec-keys/openpgp-keys-tcpdump )"
+fi
+
+src_prepare() {
+	default
+
+	if ! [[ -f VERSION ]]; then
+		echo ${PV} > VERSION || die
+	fi
+
+	eautoreconf
+}
+
+multilib_src_configure() {
+	# bug #884275
+	export LEX=flex
+
+	ECONF_SOURCE="${S}" econf \
+		$(use_enable bluetooth) \
+		$(use_enable dbus) \
+		$(use_enable rdma) \
+		$(use_enable remote) \
+		$(use_enable usb) \
+		$(use_enable yydebug) \
+		$(use_with netlink libnl) \
+		--enable-ipv6
+}
+
+multilib_src_compile() {
+	emake all shared
+	use test && emake testprogs
+}
+
+multilib_src_test() {
+	testprogs/findalldevstest || die
+}
+
+multilib_src_install_all() {
+	dodoc CREDITS CHANGES VERSION TODO README.* doc/README.*
+
+	# remove static libraries (--disable-static does not work)
+	if ! use static-libs; then
+		find "${ED}" -name '*.a' -exec rm {} + || die
+	fi
+
+	find "${ED}" -name '*.la' -delete || die
+
+	# We need this to build pppd on G/FBSD systems
+	if [[ "${USERLAND}" == "BSD" ]]; then
+		insinto /usr/include
+		doins pcap-int.h portability.h
+	fi
+}
diff --git a/net-libs/libpcap/libpcap-9999.ebuild b/net-libs/libpcap/libpcap-9999.ebuild
index 9bda8d87fb64..a229dbe01d7e 100644
--- a/net-libs/libpcap/libpcap-9999.ebuild
+++ b/net-libs/libpcap/libpcap-9999.ebuild
@@ -18,7 +18,7 @@ else
 	SRC_URI="https://www.tcpdump.org/release/${P}.tar.gz"
 	SRC_URI+=" verify-sig? ( https://www.tcpdump.org/release/${P}.tar.gz.sig )"
 
-	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~x86-solaris"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~x86-solaris"
 fi
 
 LICENSE="BSD"