net-nds/ldapvi: add missing virtual/libcrypt dependency, EAPI 7

Closes: https://bugs.gentoo.org/798948
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 52 insertions, 0 deletions

diff --git a/net-nds/ldapvi/ldapvi-1.7_p20101214-r2.ebuild b/net-nds/ldapvi/ldapvi-1.7_p20101214-r2.ebuild
new file mode 100644
index 000000000000..018f387af4a0
--- /dev/null
+++ b/net-nds/ldapvi/ldapvi-1.7_p20101214-r2.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="Manage LDAP entries with a text editor"
+HOMEPAGE="http://www.lichteblau.com/ldapvi/"
+SRC_URI="mirror://gentoo/${P}.tar.bz2"
+S="${WORKDIR}"/${P}/${PN}
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 ~hppa ppc ~sparc x86"
+IUSE="gnutls sasl"
+
+RDEPEND="dev-libs/popt
+	dev-libs/glib:2
+	net-nds/openldap
+	sys-libs/readline:=
+	sys-libs/ncurses:0=
+	virtual/libcrypt:=
+	gnutls? ( net-libs/gnutls:= )
+	!gnutls? ( dev-libs/openssl:0= )
+	sasl? ( dev-libs/cyrus-sasl:2 )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+
+	# bug #459478
+	sed -i \
+		-e '/^AC_SEARCH_LIBS/s:curses ncurses:curses ncurses tinfo:' \
+		configure.in || die
+
+	mv configure.{in,ac} || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--with-libcrypto=$(usex gnutls gnutls openssl)
+}
+
+src_install() {
+	dobin ldapvi
+	doman ldapvi.1
+	dodoc NEWS manual/{bg.png,html.xsl,manual.{css,xml}}
+}