sys-apps/cpu-x: new package, add 4.3.1

Signed-off-by: Ben Kohler <bkohler@gentoo.org>

3 files changed, 130 insertions, 0 deletions

diff --git a/sys-apps/cpu-x/Manifest b/sys-apps/cpu-x/Manifest
new file mode 100644
index 000000000000..68c0a54eff09
--- /dev/null
+++ b/sys-apps/cpu-x/Manifest
@@ -0,0 +1 @@
+DIST cpu-x-4.3.1.tar.gz 1846968 BLAKE2B bcf13a302ad108f76d3c170993385178e7b44123af6b6f3192960f69d8ee493719a408ef4e95ee82e4cbf3f151fe4dcb91a9fc9d4e53c1170c95a9ed2ad3417b SHA512 43e7bc4b82a15545e4c2f69f598a94706ef2c5f5594ff50763f71722d1b98e6dd56e907a4f35917500debf11522c5908dbebf51f515fe5a51af7282254210bc1
diff --git a/sys-apps/cpu-x/cpu-x-4.3.1.ebuild b/sys-apps/cpu-x/cpu-x-4.3.1.ebuild
new file mode 100644
index 000000000000..8f7959b187aa
--- /dev/null
+++ b/sys-apps/cpu-x/cpu-x-4.3.1.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="CPU-X"
+
+inherit cmake gnome2-utils xdg
+
+DESCRIPTION="A Free software that gathers information on CPU, motherboard and more"
+HOMEPAGE="https://x0rg.github.io/CPU-X/"
+SRC_URI="https://github.com/X0rg/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="-* ~amd64"
+IUSE="+bandwidth +dmidecode force-libstatgrab +gtk +libcpuid +libglfw +libpci +ncurses +nls opencl test"
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND="
+	dev-libs/glib:2
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/pango
+	force-libstatgrab? ( sys-libs/libstatgrab )
+	!force-libstatgrab? ( sys-process/procps:= )
+	gtk? ( >=x11-libs/gtk+-3.12:3 )
+	libcpuid? ( >=dev-libs/libcpuid-0.3.0:= )
+	libglfw? ( >=media-libs/glfw-3.3
+		media-libs/libglvnd )
+	libpci? ( sys-apps/pciutils )
+	ncurses? ( sys-libs/ncurses:=[tinfo] )
+	opencl? ( virtual/opencl )
+"
+
+DEPEND="
+	test? (
+		sys-apps/mawk
+		sys-apps/nawk
+	)
+
+	${COMMON_DEPEND}
+"
+
+BDEPEND="
+	dev-lang/nasm
+	nls? ( sys-devel/gettext )
+"
+
+RDEPEND="${COMMON_DEPEND}"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DFORCE_LIBSTATGRAB=$(usex force-libstatgrab)
+		-DGSETTINGS_COMPILE=OFF
+		-DWITH_BANDWIDTH=$(usex bandwidth)
+		-DWITH_DMIDECODE=$(usex dmidecode)
+		-DWITH_GETTEXT=$(usex nls)
+		-DWITH_GTK=$(usex gtk)
+		-DWITH_LIBCPUID=$(usex libcpuid)
+		-DWITH_LIBGLFW=$(usex libglfw)
+		-DWITH_LIBPCI=$(usex libpci)
+		-DWITH_LIBSTATGRAB=OFF
+		-DWITH_NCURSES=$(usex ncurses)
+		-DWITH_OPENCL=$(usex opencl)
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}
diff --git a/sys-apps/cpu-x/metadata.xml b/sys-apps/cpu-x/metadata.xml
new file mode 100644
index 000000000000..475445e45d94
--- /dev/null
+++ b/sys-apps/cpu-x/metadata.xml
@@ -0,0 +1,49 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>bkohler@gentoo.org</email>
+		<name>Ben Kohler</name>
+	</maintainer>
+	<longdescription>
+		<pkg>sys-process/cpu-x</pkg> is similar to CPU-Z (Windows), but, unlike
+		the latter, it is a Free and Open Source software, written in C and
+		designed for GNU/Linux. It can also be used in graphical mode by using
+		<pkg>x11-libs/gtk+</pkg>, than in text-based mode with the use of
+		<pkg>sys-libs/ncurses</pkg>.
+	</longdescription>
+	<longdescription lang="fr">
+		<pkg>sys-process/cpu-x</pkg> est similaire à CPU-Z (Windows), mais,
+		contrairement à ce dernier, c'est un logiciel Libre et Open Source,
+		écrit en C et concu pour GNU/Linux. Il peut être aussi bien utilisé en
+		mode graphique en utlisant <pkg>x11-libs/gtk+</pkg>, qu'en mode textuel
+		avec l'utilisation de <pkg>sys-libs/ncurses</pkg>.
+	</longdescription>
+	<use>
+		<flag name="bandwidth">Integrate bandwidth</flag>
+		<flag name="dmidecode">Integrate dmidecode</flag>
+		<flag name="force-libstatgrab">Use <pkg>sys-libs/libstatgrab</pkg> to instead of <pkg>sys-process/procps</pkg></flag>
+		<flag name="libcpuid">Use the <pkg>sys-libs/libcpuid</pkg> library</flag>
+		<flag name="libglfw">Use the <pkg>media-libs/glfw</pkg> library</flag>
+		<flag name="libpci">Use the <pkg>sys-apps/pciutils</pkg> library</flag>
+		<flag name="opencl">Use the <pkg>virtual/opencl</pkg> library</flag>
+	</use>
+	<use lang="fr">
+		<flag name="bandwidth">Intégrer bandwidth</flag>
+		<flag name="dmidecode">Intégrer dmidecode</flag>
+		<flag name="force-libstatgrab">Utiliser <pkg>sys-libs/libstatgrab</pkg> à la place de <pkg>sys-process/procps</pkg></flag>
+		<flag name="libcpuid">Utiliser la bibliothèque <pkg>sys-libs/libcpuid</pkg></flag>
+		<flag name="libglfw">Utiliser la bibliothèque <pkg>media-libs/glfw</pkg></flag>
+		<flag name="libpci">Utiliser la bibliothèque <pkg>sys-apps/pciutils</pkg></flag>
+		<flag name="opencl">Utiliser la bibliothèque <pkg>virtual/opencl</pkg></flag>
+	</use>
+	<upstream>
+		<maintainer status="active">
+			<name>X0rg</name>
+		</maintainer>
+		<changelog>https://raw.githubusercontent.com/X0rg/CPU-X/master/ChangeLog</changelog>
+		<doc>https://github.com/X0rg/CPU-X/wiki/</doc>
+		<bugs-to>https://github.com/X0rg/CPU-X/issues/</bugs-to>
+		<remote-id type="github">X0rg/CPU-X</remote-id>
+	</upstream>
+</pkgmetadata>