sys-apps/hdparm: Bump to version 9.60

Package-Manager: Portage-3.0.9, Repoman-3.0.2
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

1 files changed, 43 insertions, 0 deletions

diff --git a/sys-apps/hdparm/hdparm-9.60.ebuild b/sys-apps/hdparm/hdparm-9.60.ebuild
new file mode 100644
index 000000000000..1bfffb80b2fa
--- /dev/null
+++ b/sys-apps/hdparm/hdparm-9.60.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs flag-o-matic
+
+DESCRIPTION="Utility to change hard drive performance parameters"
+HOMEPAGE="https://sourceforge.net/projects/hdparm/"
+SRC_URI="mirror://sourceforge/hdparm/${P}.tar.gz"
+
+LICENSE="BSD GPL-2" # GPL-2 only
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="static"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-9.60-build.patch
+)
+
+src_prepare() {
+	default
+	use static && append-ldflags -static
+}
+
+src_configure() {
+	tc-export CC
+	export STRIP=:
+}
+
+src_install() {
+	into /
+	dosbin hdparm contrib/idectl
+
+	newinitd "${FILESDIR}"/hdparm-init-8 hdparm
+	newconfd "${FILESDIR}"/hdparm-conf.d.3 hdparm
+
+	doman hdparm.8
+	dodoc hdparm.lsm Changelog README.acoustic hdparm-sysconfig
+	docinto wiper
+	dodoc wiper/{README.txt,wiper.sh}
+	docompress -x /usr/share/doc/${PF}/wiper/wiper.sh
+}