proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 75 insertions, 0 deletions

diff --git a/sys-boot/vboot-utils/vboot-utils-1.0_p20130222.ebuild b/sys-boot/vboot-utils/vboot-utils-1.0_p20130222.ebuild
new file mode 100644
index 000000000000..1b05595346e9
--- /dev/null
+++ b/sys-boot/vboot-utils/vboot-utils-1.0_p20130222.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils rpm toolchain-funcs
+
+KEYWORDS="~amd64 ~arm ~x86"
+DESCRIPTION="Chrome OS verified boot tools"
+HOMEPAGE="http://git.chromium.org/gitweb/?p=chromiumos/platform/vboot_reference.git"
+EGIT_COMMIT="e6cf2c21a1cd6fc46b6adcaadc865e2f8bd4874e"
+MY_VERSION="${PV##*_p}git${EGIT_COMMIT:0:7}"
+MY_PV="${PN}-${MY_VERSION}"
+SRC_URI="http://kojipkgs.fedoraproject.org/packages/${PN}/${MY_VERSION}/3.fc19/src/${MY_PV}-3.fc19.src.rpm"
+LICENSE="BSD"
+SLOT="0"
+IUSE=""
+
+RDEPEND="app-arch/xz-utils:=
+	dev-libs/libyaml:=
+	dev-libs/openssl:0=
+	sys-apps/util-linux:="
+
+DEPEND="app-crypt/trousers
+	${RDEPEND}"
+
+S=${WORKDIR}
+
+src_unpack() {
+	rpm_unpack ${A}
+	unpack ./${MY_PV}.tar.xz
+	mv ./${MY_PV}/* ./ || die
+}
+
+src_prepare() {
+	epatch *.patch
+	sed -e 's:-Werror ::g' -e 's:-nostdinc ::g' \
+		-i Makefile || die
+}
+
+src_compile() {
+	mkdir "${S}"/build-main || die
+	tc-export CC AR CXX PKG_CONFIG
+	emake \
+		-j1 \
+		V=1 \
+		BUILD="${S}"/build-main \
+		ARCH=$(tc-arch) \
+		all
+	unset CC AR CXX PKG_CONFIG
+}
+
+src_test() {
+	# ARCH and HOST_ARCH must be identical in order
+	# to avoid calling qemu.
+	local arch=$(tc-arch)
+	[[ ${arch} == amd64 ]] && arch=x86_64
+	emake \
+		V=1 \
+		BUILD="${S}"/build-main \
+		ARCH=${arch} \
+		HOST_ARCH=${arch} \
+		runtests
+}
+
+src_install() {
+	emake \
+		V=1 \
+		BUILD="${S}"/build-main \
+		DESTDIR="${ED}/usr/bin" \
+		install
+	insinto /usr/share/vboot/devkeys
+	doins tests/devkeys/*
+	dodoc README
+}