sys-devel/binutils-config: bump up to 5.4

One user visible change:
- binutils-config: add support for special 'latest' version for profile switch

Closes: https://bugs.gentoo.org/765664
Package-Manager: Portage-3.0.16, Repoman-3.0.2
Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>

1 files changed, 43 insertions, 0 deletions

diff --git a/sys-devel/binutils-config/binutils-config-5.4.ebuild b/sys-devel/binutils-config/binutils-config-5.4.ebuild
new file mode 100644
index 000000000000..4795b56cc7c3
--- /dev/null
+++ b/sys-devel/binutils-config/binutils-config-5.4.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit prefix
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/binutils-config.git"
+	inherit git-r3
+else
+	SRC_URI="https://dev.gentoo.org/~slyfox/distfiles/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+
+DESCRIPTION="Utility to change the binutils version being used"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Project:Toolchain"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="+native-symlinks"
+
+# We also RDEPEND on sys-apps/findutils which is in base @system
+RDEPEND="sys-apps/gentoo-functions"
+
+src_compile() {
+	emake DESTDIR="${D}" PV="${PV}" USE_NATIVE_LINKS="$(usex native-symlinks)"
+}
+
+src_install() {
+	emake DESTDIR="${D}" PV="${PV}" install
+
+	use prefix && eprefixify "${ED}"/usr/bin/${PN}
+}
+
+pkg_postinst() {
+	# Re-register all targets. USE flags or new versions can change
+	# installed symlinks.
+	local x
+	for x in $(binutils-config -C -l 2>/dev/null | awk '$NF == "*" { print $2 }') ; do
+		binutils-config ${x}
+	done
+}