sys-fs/unionfs-fuse: 3.2 + sync 9999

Signed-off-by: Sebastian Pipping <sping@gentoo.org>

1 files changed, 48 insertions, 0 deletions

diff --git a/sys-fs/unionfs-fuse/unionfs-fuse-3.2.ebuild b/sys-fs/unionfs-fuse/unionfs-fuse-3.2.ebuild
new file mode 100644
index 000000000000..8a0d27e6c74e
--- /dev/null
+++ b/sys-fs/unionfs-fuse/unionfs-fuse-3.2.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+
+PYTHON_COMPAT=( python3_{8..11} )
+inherit python-any-r1 toolchain-funcs
+
+DESCRIPTION="Self-syncing tree-merging file system based on FUSE"
+HOMEPAGE="https://github.com/rpodgorny/unionfs-fuse"
+SRC_URI="https://github.com/rpodgorny/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-linux"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="sys-fs/fuse:3"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	test? (
+		$(python_gen_any_dep 'dev-python/pytest[${PYTHON_USEDEP}]')
+	)
+"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+python_check_deps() {
+	use test || return 0
+	python_has_version "dev-python/pytest[${PYTHON_USEDEP}]"
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)" CC="$(tc-getCC)"
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" install
+}
+
+src_test() {
+	[[ -e /dev/fuse ]] || return 0
+	addwrite /dev/fuse
+	pytest -vv || die "Tests fail with ${EPYTHON}"
+}