sys-kernel/gentoo-kernel-bin: bump to 5.10.22 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 114 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 7f4282757b48..86d47708b3ec 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -38,6 +38,7 @@ DIST gentoo-kernel-5.10.21-1.amd64.xpak 64098921 BLAKE2B 77e28d143903a6930867093
 DIST gentoo-kernel-5.10.21-1.arm64.xpak 59332791 BLAKE2B ddb667553bb19f66a42472180a7fdbf2fe26a7481562b6a72eac91af39caff8e10182b9b5ed25f67a7265b06aeb58832ac0559de417e0798d21ccad0a5e808ae SHA512 6dd27944b06af90872087f2613ec703d5c5972a38954de363cabd1a61b6cff929c8e8445cc698c1faf6a6bd70d75c307e787731eb9d2def6b0a29067bfca7fa6
 DIST gentoo-kernel-5.10.21-1.x86.xpak 57068126 BLAKE2B 4d087cfc6e76f829f510b91fe898b7f3ee1e8e735a3eb08345d92e62c3a91a855fea5f1704c07574e6e8f56d3da499afedc83bb6cf8276abb49a878c8724687d SHA512 a62737b43fbd8607bb5a61025064d5dde7ee41c7ad4e6d017642b26a89eee584fcf8125044ae84fa8b37faf7c839edf99d47d9826611060a2bf3bd2d5d8bcf6d
 DIST gentoo-kernel-5.10.22-1.amd64.xpak 64085208 BLAKE2B 2ad4a5ac3391bf34c15a190a81772d48ca1bad6cae671a26a9dac70550b671f05512e37fa20370fb970a1796444b05c9f26b2846bbf9acb82369bd88d6766b1c SHA512 27722129bdd20babbd2a37b5b7bc0fda446d0726bf881ffddb4c6a4fde7e7427abb4f41a36943ab462416091f0414ae5e1fea5c743a3a701409f936472ab742b
+DIST gentoo-kernel-5.10.22-1.arm64.xpak 59289046 BLAKE2B fdacceeb2cc5078438f65f6ef5a30669a3c5f20d66c68578265574af56afcf810625d321f6ee889fb31ac6e2ee6a9e92256dfde8d22364747667c94dc0d1e1b5 SHA512 e0af4c4e921621a342b901e2b8e1c2ca19817d5f412a106d2718afc8c967163a2068056cb29b0c8ae739bf77d29277a2fb493c028ca4477af59b68fff79e63da
 DIST gentoo-kernel-5.10.22-1.x86.xpak 57048115 BLAKE2B a07ef32fa35da33d9b5d56c66c18465e3ae89edb801763e87a2de543fdaa37722e063f64da42074baf42f26b990dfbf9e1e7d102943dc5edf791727d568d776f SHA512 f9f85ac08c1ca19715ecda74242ceaee600e2ae83aa6dfe5fa862dfceecfb0d1f16bdebbeb96bbf706555e717e4200a7de705017b62788f74bc16561d2372ac6
 DIST gentoo-kernel-5.11.2-1.amd64.xpak 64830406 BLAKE2B f9c5d0591a175e497e3ff9f9c12e855e0c7db90aaf28fef5bbc695604c5745e13e3cd16001eb75216c55868497954a58738a7eca2314f077548650ae27b73620 SHA512 9a05cf8ce3218ac7e6b880624cbdc67d7fa221f0440f920de70f883a33978df08297184eeeb7a5b3c420da34ba7cb9ebc38f11c9a4979cf5d8a5c7a33e82b85a
 DIST gentoo-kernel-5.11.2-1.arm64.xpak 59866719 BLAKE2B 5c8e59242ac3512488afbc1335845294f6ed6b5f7cf0674c4655689b4e93284b110295da479c14f3bd70111c5f652a2c7c641bd34b06f9d7b21bacdb3965b746 SHA512 978891967b1b2c59ca1d4e77bd7d622585532e39cdaceae087a72c6f72d57764cd9dcdcad918ddb1c2d92a42ddc9859baf532971a280cbbe7c4811acb7cc3f5c
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.22-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.22-r1.ebuild
new file mode 100644
index 000000000000..18c02d4c0f39
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.22-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}
+	!sys-kernel/vanilla-kernel:${SLOT}
+	!sys-kernel/vanilla-kernel-bin:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${PV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${PV}" \
+		"usr/src/linux-${PV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${PV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${PV}"/ || die
+}