sys-kernel/gentoo-kernel-bin: bump to 5.10.49-r1 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 115 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 92bcba37f7d8..8f35d83fdc1e 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -27,6 +27,7 @@ DIST gentoo-kernel-5.10.48-1.amd64.xpak 65536136 BLAKE2B be9827d86c0fe12b750aa5e
 DIST gentoo-kernel-5.10.48-1.arm64.xpak 59043938 BLAKE2B 3747e7835e6d3ac4b0659d97a9d45eb9276a09258dac16488e7d701202d524a91406c179a388e215dea878614d66d01a5ffb4d45e898662d11dc597535993571 SHA512 167b5760026c6fff7bcc1ee4b5ae6e6befc287dab065495fdd712fef5249571ba6c72a270e54d9ff4ba41b81a08cced954994016b63e37813911372d686e3046
 DIST gentoo-kernel-5.10.48-1.x86.xpak 57223594 BLAKE2B cdaf9e1f4d49cfb1e772a5c5ad92bfcdca846a16a540032136845c1fc7256c6df405e2d1613377dc5046209a750bfb9b6d543203d604853b2f2d7dfb6e786c5e SHA512 3c1e1895a89cff6f03fda61613c8bc1c62cce4c98992e354b9572965728ece2e7556121edc725a942a23b9eccdc52d6282ef3bd929cb79052ce2ff495a849db4
 DIST gentoo-kernel-5.10.49-1.amd64.xpak 65485861 BLAKE2B 8968b059a030ec15baa34647f0738e7f7666e889feb070e6476a38fd4c13d60e30b0837b62e258dc74c8e8b936c7dc0c717c110e117750e79bb24980530d2ca8 SHA512 d3524763ee27f9529ea8dcc02335f59b04c2da8fcb9c093154b38632fdcee654e2641c888e4fcc9edfa54131763d2182d34df4ef8dc68a5033921130ecb87f9a
+DIST gentoo-kernel-5.10.49-1.arm64.xpak 59061383 BLAKE2B aaa58b2c6ffe3cba529597af8b6fffa0d4c091dda190a1e59f53787788b8884e36f0e0b56e48f12a861f97713992972f5cbfa1eecd6ca21ca1a4b2d21590d01f SHA512 c8d05a0d7c5296d0000e16c04c23ecbb290205a1fc502b7f923b83f8cc366f421a9bef20204977144d2ced491a705b0bc291da507861172514831b1e59db3921
 DIST gentoo-kernel-5.10.49-1.x86.xpak 57214239 BLAKE2B 9f9740028a1c6498781a283f0fe823a137c9e49c3c51a217a89c54aaf9bd3ebf8c8c4205ac6c8e92c0a9b8c375b40b27d30054db05ce30908a9f40be17a3cfc4 SHA512 65626b07476e7d6c82643691f0197e63dd2756789b1a241c6918b305e1dc98500e27114fa781c93f46028aeff6f4194f0b84768d155829add3d50eb8febeebcd
 DIST gentoo-kernel-5.12.15-1.amd64.xpak 66395917 BLAKE2B b77c5e26863dc1c10da3c82904ef035f93c7bbbf60925f7c91836b7cfbb3d32335a8cad78a9b1a90a6d462f34fb798c393f7f992c54ffe6e1a5391b1e63652a4 SHA512 3efe58c6e9d948981fe51fc93ceb73de2f9a049cd396c62e743b3c5033eaf60b05d3100b2377060d1ba6245118281a49447bb5404dd4cc12b616a682fc4c252a
 DIST gentoo-kernel-5.12.15-1.arm64.xpak 59971350 BLAKE2B 4231ed09d6efd9acae82078d259bef241223770fc95c24145a940ff3e4d712cfe52677a358d4fe26a6bf74129feaa3abad67e2d17eedd1e04f34758fd7ac5e1e SHA512 9eb582dab725c1716b777986e0adf90b353ca481763b27c65240d6b4d8e52d54ca394848b3ff7977651606341e39fbc19b0002caaa8174916f298bfe480087d9
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.49-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.49-r1.ebuild
new file mode 100644
index 000000000000..b63276300c50
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.49-r1.ebuild
@@ -0,0 +1,114 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}