www-apps/cgp: bump to EAPI=7.

Closes: https://bugs.gentoo.org/669774
Signed-off-by: Conrad Kostecki <conrad@kostecki.com>
Package-Manager: Portage-2.3.51, Repoman-2.3.11
Closes: https://github.com/gentoo/gentoo/pull/10254
Signed-off-by: Patrice Clement <monsieurp@gentoo.org>

1 files changed, 54 insertions, 0 deletions

diff --git a/www-apps/cgp/cgp-1_p20180620-r1.ebuild b/www-apps/cgp/cgp-1_p20180620-r1.ebuild
new file mode 100644
index 000000000000..6fe5fc73bda7
--- /dev/null
+++ b/www-apps/cgp/cgp-1_p20180620-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit webapp
+
+MY_PN="${PN^^}"
+MY_PV="1920ca24a067ac157a6bd8f3c017f4c6244ae245"
+
+DESCRIPTION="A graphical web-based front-end for visualizing RRD collected by collectd"
+HOMEPAGE="https://github.com/pommi/CGP"
+SRC_URI="https://github.com/pommi/${MY_PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="CC-BY-2.0 GPL-2+ GPL-3 MIT"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-lang/php[json]
+	net-analyzer/rrdtool[graph]
+	virtual/httpd-php
+"
+
+need_httpd_cgi
+
+S="${WORKDIR}/${MY_PN}-${MY_PV}"
+
+DOCS=( "README.md" "doc/CHANGELOG" "doc/nginx.conf" )
+
+src_install() {
+	webapp_src_preinst
+
+	einstalldocs
+
+	# Since the docs are already installed, remove them from htdocs
+	# The file doc/CHANGELOG is needed, as CGP reads from there it's version
+	rm -r .gitignore doc/LICENSE doc/nginx.conf || die
+
+	insinto "${MY_HTDOCSDIR}"
+	doins -r .
+
+	webapp_src_install
+}
+
+pkg_postinst() {
+	webapp_pkg_postinst
+
+	einfo "The command shell_exec must not be disabled"
+	einfo "through the disable_functions php.ini directive."
+	einfo "It must allow execution of the rrdtool program."
+	einfo ""
+	einfo "An configuration file for www-servers/nginx"
+	einfo "has been installed as an example."
+}