www-apps/radicale: bump to 3.1.8

Signed-off-by: Henning Schild <henning@hennsch.de>
Closes: https://github.com/gentoo/gentoo/pull/26454
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

2 files changed, 94 insertions, 0 deletions

diff --git a/www-apps/radicale/Manifest b/www-apps/radicale/Manifest
index 8518cd1fb662..c74fcb087f57 100644
--- a/www-apps/radicale/Manifest
+++ b/www-apps/radicale/Manifest
@@ -1,2 +1,3 @@
 DIST radicale-3.1.5.tar.gz 136725 BLAKE2B 574032fc9a4010db2de0066758093b74fb29e43c3e8f3328441c92af99827a5f4174ac3ddbc2573083642af4c68073c470ce64ae7689b537a72aa0b813b641b8 SHA512 0febad350e970e4f0ef8199472bb94a81a2a412be2b55c1baee16967b39bf9a5f7b9e8aa7c95a19beedf2f8b2d871382aa0727803432575bff248bc0137adce3
 DIST radicale-3.1.7.tar.gz 137416 BLAKE2B 3192acd1e4ee9a63803bcc7aac7b62ae50a94a88d294f3299508dbd1f7a42cb79ea87dc2675509c1b12f76e75e37635b1a97672db61b09f5dfaefc5bbc1d616e SHA512 04ae2072a90f303dd18de3a2cf6474263ca9650ee87ee72be0d7177ad2f2f61f4860784674bac8dbff2c2679ac45acd03aa38c02b00349f01669c6cf4a474605
+DIST radicale-3.1.8.tar.gz 137123 BLAKE2B ec855138aa18508da5375c5bde854cee4d4110fb75437cc1472afd3b589dfa523031cdd1b8a51a0f6a74dfe819308acd068b979acde32c05941d113d9d289f1e SHA512 5c4b55ee9cfc5060a0e0cf1f284d2c5a354bcabd7a088214e917fabb0083bcd172fd92aeb59b1f869f34e04f8c276efbed15c2a3ff2fdbc81b2220586bbaf31b
diff --git a/www-apps/radicale/radicale-3.1.8.ebuild b/www-apps/radicale/radicale-3.1.8.ebuild
new file mode 100644
index 000000000000..113b188e44b1
--- /dev/null
+++ b/www-apps/radicale/radicale-3.1.8.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1 systemd
+
+DESCRIPTION="A simple CalDAV calendar server"
+HOMEPAGE="https://radicale.org/"
+SRC_URI="https://github.com/Kozea/Radicale/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+
+MY_P="Radicale-${PV}"
+
+RDEPEND="
+	>=acct-user/radicale-0-r2
+	acct-group/radicale
+	dev-python/bcrypt[${PYTHON_USEDEP}]
+	dev-python/defusedxml[${PYTHON_USEDEP}]
+	dev-python/passlib[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/vobject[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	sys-apps/util-linux
+"
+
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/waitress[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests --install pytest
+
+S="${WORKDIR}/${MY_P}"
+
+RDIR=/var/lib/"${PN}"
+
+DOCS=( DOCUMENTATION.md CHANGELOG.md )
+
+src_prepare() {
+	sed -i '/^addopts =/d' setup.cfg || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	epytest radicale/tests/
+}
+
+python_install_all() {
+	rm README* || die
+	# init file
+	newinitd "${FILESDIR}"/radicale-r3.init.d radicale
+	systemd_dounit "${FILESDIR}/${PN}.service"
+
+	# directories
+	keepdir "${RDIR}"
+	fperms 0750 "${RDIR}"
+	fowners "${PN}:${PN}" "${RDIR}"
+
+	# config file
+	insinto /etc/"${PN}"
+	doins config
+
+	# fcgi and wsgi files
+	exeinto /usr/share/"${PN}"
+	doexe radicale.wsgi
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	local _erdir="${EROOT}${RDIR}"
+
+	einfo "A sample WSGI script has been put into ${EROOT}/usr/share/${PN}."
+	einfo "You will also find there an example FastCGI script."
+	if [[ $(stat --format="%U:%G:%a" "${_erdir}") != "${PN}:${PN}:750" ]]
+	then
+		ewarn ""
+		ewarn "Unsafe file permissions detected on ${_erdir}."
+		ewarn "This probably comes from an earlier version of this ebuild."
+		ewarn "To fix run:"
+		ewarn "#  \`chown -R ${PN}:${PN} ${_erdir}\`"
+		ewarn "#  \`chmod 0750 ${_erdir}\`"
+		ewarn "#  \`chmod -R o= ${_erdir}\`"
+	fi
+}