www-client/microsoft-edge: remove old

Signed-off-by: Stephan Hartmann <sultan@gentoo.org>

2 files changed, 0 insertions, 117 deletions

diff --git a/www-client/microsoft-edge/Manifest b/www-client/microsoft-edge/Manifest
index 132c170381f1..584c68e3a8f0 100644
--- a/www-client/microsoft-edge/Manifest
+++ b/www-client/microsoft-edge/Manifest
@@ -1,2 +1 @@
 DIST microsoft-edge-stable_100.0.1185.29-1_amd64.deb 119102768 BLAKE2B d47eb7c693efc288949616d121cbec66dc97f7b7d82d35f26b5751590a462568ad9d2204d62a45b43ea7d3ce7f0072cef32c44a2333505adb0aab40f80affb5b SHA512 0805ce05ec837b51a4e11a29c52976d785e31489f9f3ae7d11ce428fa5673ffa24fba2b2b948931efb49af63e97595e05b3791d70d30b9574c7f839c35dbc92f
-DIST microsoft-edge-stable_99.0.1150.55-1_amd64.deb 117772024 BLAKE2B 009d6396b284ff620bb49fce6861a61d743692b8926a20d6d97ce7c2eceee5e91336db01272a07e0d78d3492ef99692b6861f826b23deff8126199b6a973b1f6 SHA512 b45e9c9cb13d871f0c8be79917da518e984d27fa61eb166dfd5d7e8030d23de2f8e5eac8f95f1888d42106d71764b6d25d4a5eab5217f2c91e9e19e219cd43d0
diff --git a/www-client/microsoft-edge/microsoft-edge-99.0.1150.55.ebuild b/www-client/microsoft-edge/microsoft-edge-99.0.1150.55.ebuild
deleted file mode 100644
index 3db12034b572..000000000000
--- a/www-client/microsoft-edge/microsoft-edge-99.0.1150.55.ebuild
+++ /dev/null
@@ -1,116 +0,0 @@
-# Copyright 2011-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI="8"
-
-inherit chromium-2 desktop pax-utils unpacker xdg
-
-DESCRIPTION="The web browser from Microsoft"
-HOMEPAGE="https://www.microsoft.com/en-us/edge"
-
-if [[ ${PN} == microsoft-edge ]]; then
-	MY_PN=${PN}-stable
-else
-	MY_PN=${PN}
-fi
-
-KEYWORDS="-* amd64"
-
-MY_P="${MY_PN}_${PV}-1"
-
-SRC_URI="https://packages.microsoft.com/repos/edge/pool/main/m/${MY_PN}/${MY_P}_amd64.deb"
-
-LICENSE="microsoft-edge"
-SLOT="0"
-RESTRICT="bindist mirror strip"
-IUSE="+mip"
-
-RDEPEND="
-	app-accessibility/at-spi2-atk:2
-	app-accessibility/at-spi2-core:2
-	app-misc/ca-certificates
-	dev-libs/atk
-	dev-libs/expat
-	dev-libs/glib:2
-	dev-libs/nspr
-	dev-libs/nss
-	media-fonts/liberation-fonts
-	media-libs/alsa-lib
-	media-libs/mesa[gbm(+)]
-	net-misc/curl[ssl]
-	net-print/cups
-	sys-apps/dbus
-	sys-apps/util-linux
-	sys-libs/glibc
-	x11-libs/cairo
-	x11-libs/gdk-pixbuf:2
-	x11-libs/gtk+:3[X]
-	x11-libs/libdrm
-	x11-libs/libX11
-	x11-libs/libXcomposite
-	x11-libs/libXdamage
-	x11-libs/libXext
-	x11-libs/libXfixes
-	x11-libs/libXrandr
-	x11-libs/libxcb
-	x11-libs/libxkbcommon
-	x11-libs/libxshmfence
-	x11-libs/pango
-	x11-misc/xdg-utils
-	mip? ( app-crypt/libsecret )
-"
-
-QA_PREBUILT="*"
-QA_DESKTOP_FILE="usr/share/applications/microsoft-edge.*\\.desktop"
-S=${WORKDIR}
-EDGE_HOME="opt/microsoft/msedge${PN#microsoft-edge}"
-
-pkg_nofetch() {
-	eerror "Please wait 24 hours and sync your tree before reporting a bug for microsoft-edge fetch failures."
-}
-
-pkg_pretend() {
-	# Protect against people using autounmask overzealously
-	use amd64 || die "microsoft-edge only works on amd64"
-}
-
-pkg_setup() {
-	chromium_suid_sandbox_check_kernel_config
-}
-
-src_unpack() {
-	:
-}
-
-src_install() {
-	dodir /
-	cd "${ED}" || die
-	unpacker
-
-	rm _gpgorigin || die
-
-	rm -r etc usr/share/menu || die
-	mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
-
-	gzip -d usr/share/doc/${PF}/changelog.gz || die
-	gzip -d usr/share/man/man1/${MY_PN}.1.gz || die
-	if [[ -L usr/share/man/man1/${PN}.1.gz ]]; then
-		rm usr/share/man/man1/${PN}.1.gz || die
-		dosym ${MY_PN}.1 usr/share/man/man1/${PN}.1
-	fi
-
-	local suffix=
-	[[ ${PN} == microsoft-edge-beta ]] && suffix=_beta
-	[[ ${PN} == microsoft-edge-dev ]] && suffix=_dev
-
-	local size
-	for size in 16 24 32 48 64 128 256 ; do
-		newicon -s ${size} "${EDGE_HOME}/product_logo_${size}${suffix}.png" ${PN}.png
-	done
-
-	if ! use mip; then
-		rm "${EDGE_HOME}"/libmip_{core,protection_sdk}.so || die
-	fi
-
-	pax-mark m "${EDGE_HOME}/msedge"
-}