x11-wm/enlightenment: bump to 0.24.2

Signed-off-by: Joonas Niilola <juippis@gentoo.org>

2 files changed, 112 insertions, 0 deletions

diff --git a/x11-wm/enlightenment/Manifest b/x11-wm/enlightenment/Manifest
index 3cc2ff5e50a0..d332eb648026 100644
--- a/x11-wm/enlightenment/Manifest
+++ b/x11-wm/enlightenment/Manifest
@@ -1 +1,2 @@
 DIST enlightenment-0.24.1.tar.xz 28713452 BLAKE2B 1d4713a4887a687a5425888e65b358cd01fe12e42865799265f5092dc6784eb29c25b5563805d1c7be9856037b0570027c2f01a8eb848299e7729d905e291470 SHA512 3835d898f1fdb96ab6539543e9af910b4a9078372af5cfd90abb33c0d5ecb41496499629c54613e3fec4c230233b69bf1abde68f3ffba4996c69979a526da418
+DIST enlightenment-0.24.2.tar.xz 28716060 BLAKE2B 432722693beaece97eeb318a1120b6101bf76e1536347b824b00ba4378326c093f3333eefa634d7266a59c09dc4337c8bd1f9a4d89e0a4c9a223fdcacd924fa0 SHA512 5d96b17d89e822271048a0a6a8356658fd02680f54da2f15dde7c632752bbf0a396eaf23986164402e61f631e68937b3ba7c29d9dd787ddd470cff4a390abace
diff --git a/x11-wm/enlightenment/enlightenment-0.24.2.ebuild b/x11-wm/enlightenment/enlightenment-0.24.2.ebuild
new file mode 100644
index 000000000000..bf2169b4ee55
--- /dev/null
+++ b/x11-wm/enlightenment/enlightenment-0.24.2.ebuild
@@ -0,0 +1,111 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit eutils meson xdg-utils
+
+DESCRIPTION="Enlightenment window manager"
+HOMEPAGE="https://www.enlightenment.org"
+SRC_URI="https://download.enlightenment.org/rel/apps/${PN}/${P}.tar.xz"
+
+LICENSE="BSD-2"
+SLOT="0.17/${PV%%_*}"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+IUSE="acpi bluetooth connman doc geolocation nls pam policykit systemd udisks wayland wifi xwayland"
+
+REQUIRED_USE="xwayland? ( wayland )"
+
+RDEPEND=">=dev-libs/efl-1.24.1[eet,fontconfig,X]
+	virtual/udev
+	x11-libs/libXext
+	x11-libs/libxcb
+	x11-libs/xcb-util-keysyms
+	x11-misc/xkeyboard-config
+	acpi? ( sys-power/acpid )
+	bluetooth? ( net-wireless/bluez )
+	connman? ( dev-libs/efl[connman] )
+	geolocation? ( app-misc/geoclue:2.0 )
+	pam? ( sys-libs/pam )
+	policykit? ( sys-auth/polkit )
+	systemd? ( sys-apps/systemd )
+	udisks? ( sys-fs/udisks:2 )
+	wayland? (
+		>=dev-libs/efl-1.22.0[drm,wayland]
+		dev-libs/wayland
+		x11-libs/libxkbcommon
+		x11-libs/pixman
+	)
+	xwayland? (
+		dev-libs/efl[X,wayland]
+		x11-base/xorg-server[wayland]
+	)"
+BDEPEND="virtual/pkgconfig
+	nls? ( sys-devel/gettext )"
+DEPEND="${RDEPEND}"
+
+src_configure() {
+	local emesonargs=(
+		-D device-udev=true
+		-D install-enlightenment-menu=true
+
+		-D install-sysactions=true
+		-D install-system=true
+		-D mount-eeze=false
+
+		-D packagekit=false
+
+		$(meson_use udisks mount-udisks)
+		$(meson_use bluetooth bluez5)
+		$(meson_use connman)
+		$(meson_use geolocation)
+		$(meson_use nls)
+		$(meson_use pam)
+		$(meson_use policykit polkit)
+		$(meson_use systemd)
+		$(meson_use wayland wl)
+		$(meson_use wifi wireless)
+		$(meson_use xwayland)
+	)
+
+	if ! use wayland; then
+		emesonargs+=(
+			-D wl-buffer=false
+			-D wl-desktop-shell=false
+			-D wl-drm=false
+			-D wl-text-input=false
+			-D wl-weekeyboard=false
+			-D wl-wl=false
+			-D wl-x11=false
+		)
+	fi
+
+	meson_src_configure
+}
+
+src_install() {
+	use doc && local HTML_DOCS=( doc/. )
+	meson_src_install
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+
+	elog "Additional programs to complete full EFL suite: "
+	optfeature "office file thumbnails" app-office/libreoffice app-office/libreoffice-bin
+	optfeature "an EFL-based IDE" dev-util/edi
+	optfeature "image viewer" media-gfx/ephoto
+	optfeature "ConnMan user interface for Enlightenment" net-misc/econnman
+	optfeature "system and process monitor" sys-process/evisum
+	optfeature "feature rich terminal emulator" x11-terms/terminology
+	optfeature "a modern flat enlightenment WM theme" x11-themes/e-flat-theme
+	optfeature "a matching GTK theme" x11-themes/e-gtk-theme
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}