2 files changed, 91 insertions, 0 deletions
diff --git a/net-misc/nextcloud-client/Manifest b/net-misc/nextcloud-client/Manifest
index 1bbae7c2d523..8df33052535f 100644
--- a/net-misc/nextcloud-client/Manifest
+++ b/net-misc/nextcloud-client/Manifest
@@ -2,3 +2,4 @@ DIST nextcloud-client-2.6.5.tar.gz 19134736 BLAKE2B 12defed7dc9a23622d49228c2e78
 DIST nextcloud-client-3.0.2.tar.gz 19114545 BLAKE2B a6aa041708d110fbdca082476e65ccc8fec189948aa64020a27beabe2d7b3df474ae3313b5aef0e15f3498cf974cf414eb4934417cea206b021e4e212351a088 SHA512 188f878457baba14f01ca6c0f83100bcc64feaf5e3da86903d59d8b7c553c89f88252c1410cd153952950f91429af680b1901f3f9de951bfd06a06c176d44e7d
 DIST nextcloud-client-3.0.3.tar.gz 19202718 BLAKE2B b5e09be514ede6e323e9624df38aad10969c0fdae7bc7baaeb9da4628dfa1c44a4fb6b5f6b4b83ff92b0eedbbe1ffbcf54da43d5e71923979b8649db54b05d7c SHA512 aa9e9897dae74919f11817f8aad139378a2a26df6663f3c9ee9c9e1d229b537daa9e9ed9f3ba292f8e299017f7ef5d863257a26858af159e7e76c7247d7c244d
 DIST nextcloud-client-3.1.0.tar.gz 19265221 BLAKE2B a065c1498d20b3b7ae3ca1c6b85cf81685b237a5c469aa2e01a1e0c0365c1e64db89758d7cba204035a034fb1357b7644545345fd4b98a6a88f0e5458357c206 SHA512 26c886f933fbed944b5a587dff43f3e56edfa7d36f4b0200ea1a77b0e1c28db22794ac00dbe5577d2299d733dc23c2ff7061d6a8a679bd0948431aaacd40d5f5
+DIST nextcloud-client-3.1.1.tar.gz 19440799 BLAKE2B ae6ef7fbff4b7b5c9a5728a30558000cd781348dd07aba068af5b123ec629e1661b52cd63b50bf45c593411866bc607dfcc3112713fa2aea3eabfda7ce969614 SHA512 1f60266ff6d413a614261ae8b6c75ba6bc5cdb534f1906039b47cb7d593d12d72013d277dc12c0bfc5c5919322438543736a7cdff056949d80e093538fd04209
diff --git a/net-misc/nextcloud-client/nextcloud-client-3.1.1.ebuild b/net-misc/nextcloud-client/nextcloud-client-3.1.1.ebuild
new file mode 100644
index 000000000000..a3dd780f6e5f
--- /dev/null
+++ b/net-misc/nextcloud-client/nextcloud-client-3.1.1.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake xdg
+
+DESCRIPTION="Desktop Syncing Client for Nextcloud"
+HOMEPAGE="https://github.com/nextcloud/desktop"
+SRC_URI="https://github.com/nextcloud/desktop/archive/v${PV/_/-}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="CC-BY-3.0 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc dolphin libressl nautilus test"
+
+COMMON_DEPEND=">=dev-db/sqlite-3.4:3
+	dev-libs/qtkeychain[qt5(+)]
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtquickcontrols2:5
+	dev-qt/qtsql:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwebengine:5[widgets]
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	sys-fs/inotify-tools
+	dolphin? (
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/kio:5
+	)
+	!libressl? ( >=dev-libs/openssl-1.1.0:0= )
+	libressl? ( >=dev-libs/libressl-3.1:0= )
+	nautilus? ( dev-python/nautilus-python )"
+
+RDEPEND="${COMMON_DEPEND}"
+DEPEND="${COMMON_DEPEND}
+	dev-qt/linguist-tools:5
+	doc? (
+		dev-python/sphinx
+		dev-tex/latexmk
+		dev-texlive/texlive-latexextra
+		virtual/latex-base
+	)
+	dolphin? ( kde-frameworks/extra-cmake-modules )
+	test? (
+		dev-util/cmocka
+		dev-qt/qttest:5
+	)"
+
+RESTRICT="!test? ( test )"
+
+S=${WORKDIR}/desktop-${PV/_/-}
+
+src_prepare() {
+	# Keep tests in ${T}
+	sed -i -e "s#\"/tmp#\"${T}#g" test/test*.cpp || die
+
+	if ! use nautilus; then
+		pushd shell_integration > /dev/null || die
+		cmake_comment_add_subdirectory nautilus
+		popd > /dev/null || die
+	fi
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+		-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
+		-DCMAKE_DISABLE_FIND_PACKAGE_Sphinx=$(usex !doc)
+		-DCMAKE_DISABLE_FIND_PACKAGE_KF5=$(usex !dolphin)
+		-DNO_SHIBBOLETH=yes
+		-DUNIT_TESTING=$(usex test)
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	if ! use doc ; then
+		elog "Documentation and man pages not installed"
+		elog "Enable doc USE-flag to generate them"
+	fi
+}