1 files changed, 40 insertions, 0 deletions
diff --git a/app-emulation/conmon/conmon-2.0.0.ebuild b/app-emulation/conmon/conmon-2.0.0.ebuild
new file mode 100644
index 000000000000..2f415a695537
--- /dev/null
+++ b/app-emulation/conmon/conmon-2.0.0.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KEYWORDS="~amd64"
+DESCRIPTION="An OCI container runtime monitor"
+HOMEPAGE="https://github.com/containers/conmon"
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="systemd"
+EGIT_COMMIT="e217fdff82e0b1a6184a28c43043a4065083407f"
+SRC_URI="${HOMEPAGE}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+RDEPEND="dev-libs/glib:=
+	systemd? ( sys-apps/systemd:= )"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+
+	if ! use systemd; then
+		sed -e 's| $(PKG_CONFIG) --exists libsystemd-journal | false |' \
+			-e 's| $(PKG_CONFIG) --exists libsystemd | false |' \
+			-i Makefile || die
+	fi
+}
+
+src_compile() {
+	emake GIT_COMMIT="${EGIT_COMMIT}" \
+		all
+}
+
+src_install() {
+	emake DESTDIR="${D}" \
+		PREFIX="/usr" \
+		install
+	dodir /usr/libexec/podman
+	ln "${ED}/usr/"{bin,libexec/podman}/conmon || die
+	dodoc README.md
+}