1 files changed, 54 insertions, 0 deletions
diff --git a/app-i18n/libime/libime-1.1.3.ebuild b/app-i18n/libime/libime-1.1.3.ebuild
new file mode 100644
index 000000000000..3d962ae4153e
--- /dev/null
+++ b/app-i18n/libime/libime-1.1.3.ebuild
@@ -0,0 +1,54 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Fcitx5 Next generation of fcitx "
+HOMEPAGE="https://fcitx-im.org/"
+SRC_URI="https://download.fcitx-im.org/fcitx5/libime/libime-${PV}_dict.tar.xz"
+
+LICENSE="LGPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=app-i18n/fcitx-5.1.5:5
+	app-arch/zstd:=
+	dev-libs/boost:=
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	kde-frameworks/extra-cmake-modules:0
+	virtual/pkgconfig
+	doc? (
+		app-doc/doxygen
+		dev-texlive/texlive-fontutils
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/${P}-use-c++11-for-kenlm.patch"
+	"${FILESDIR}/${P}-fix-the-nanf-value-issue-on-musl.patch"
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_DOC=$(usex doc)
+		-DENABLE_TEST=$(usex test)
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	use doc && cmake_src_compile doc
+}
+
+src_install() {
+	cmake_src_install
+	use doc && dodoc -r "${BUILD_DIR}"/doc/*
+}