2 files changed, 77 insertions, 0 deletions
diff --git a/dev-libs/libsavitar/Manifest b/dev-libs/libsavitar/Manifest
index 4ffc1c2f7db4..393650d2b34f 100644
--- a/dev-libs/libsavitar/Manifest
+++ b/dev-libs/libsavitar/Manifest
@@ -1,2 +1,3 @@
 DIST libsavitar-4.6.1.tar.gz 98202 BLAKE2B 8025d11316fb777a037c01fb9411a6368e5e7a1b64c4a695a114ff94c1a2802d4eaeb6c8512e14db74ddbbffabd2bc98f93f61adfc2cbdc7ef329d30b105bd4b SHA512 49a0f2e98bc26d84b638d6eb44f9fd93811d92ad398f3c85b1abf2cca3172667315b907d30807eb70b497bd652d95cd443c8cc4daa68c8852787ef46fda47cc2
 DIST libsavitar-4.7.0.tar.gz 99070 BLAKE2B 3e27624a62568b8d45ddf8fde60a0377faa81eb9e031e32e935d992304b7249d4f3fa7d9bc45b370882e203368a90ad48347faa600f339d096c67432e23d8ddc SHA512 bd19d3ee8be570791bf4f3d5be5eb44d5bba3181a693633d5703ba91c78d3725dbe051c888ec60cea057790a561beeb98b96c41e6584f630f2410bdb97e0cb4d
+DIST libsavitar-4.8.0.tar.gz 99030 BLAKE2B a1c1e252aa942114a1d7112d2e661b5e63403502642826c6b92c408c8eabd3d9fb12b44dc286f9a0dce3d42f473adae2441d357f237c903c8a0df936c41f9f37 SHA512 65d31986b120c9e717b10d0bac420f2582d9f1b44051d88f89475408d1f7997e144001c61f180eac554de33f1f8c1ec9555a6c23bdd797315624f57030f7ec8c
diff --git a/dev-libs/libsavitar/libsavitar-4.8.0.ebuild b/dev-libs/libsavitar/libsavitar-4.8.0.ebuild
new file mode 100644
index 000000000000..3afa1673bb74
--- /dev/null
+++ b/dev-libs/libsavitar/libsavitar-4.8.0.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..8} )
+
+inherit cmake python-single-r1
+
+MY_PN="libSavitar"
+
+DESCRIPTION="C++ implementation of 3mf loading with SIP python bindings"
+HOMEPAGE="https://github.com/Ultimaker/libSavitar"
+SRC_URI="https://github.com/Ultimaker/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0/3"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+IUSE="+python static-libs test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="${PYTHON_DEPS}
+	dev-libs/pugixml
+	$(python_gen_cond_dep '
+		dev-python/sip[${PYTHON_MULTI_USEDEP}]
+	')"
+
+DEPEND="${RDEPEND}
+	test? (
+		dev-cpp/gtest
+		dev-cpp/tbb
+	)"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+BUILD_DIR="${S}/build"
+
+PATCHES=( "${FILESDIR}/${PN}-4.7.0-use-system-pugixml.patch" )
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	# remove bundled pugixml
+	rm -r "${S}"/pugixml || die
+
+	find "${S}"/src -type f -name '*.cpp' -o -name '*.h' | xargs sed -i \
+		-e 's "../pugixml/src/pugixml.hpp" <pugixml.hpp> g' || die
+
+	if use test; then
+		find "${S}"/tests -type f -name '*.cpp' -o -name '*.h' | xargs sed -i \
+			-e 's "../pugixml/src/pugixml.hpp" <pugixml.hpp> g' || die
+	fi
+
+	# find SIP for current python version, not the latest installed
+	sed -i -e "s/find_package(Python3 3.4 REQUIRED/find_package(Python3 ${EPYTHON##python} EXACT REQUIRED/g" \
+		CMakeLists.txt cmake/FindSIP.cmake || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_PYTHON=$(usex python ON OFF)
+		-DBUILD_STATIC=$(usex static-libs ON OFF)
+		-DBUILD_TESTS=$(usex test ON OFF)
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	cmake_src_test
+}