1 files changed, 0 insertions, 106 deletions
diff --git a/dev-python/httpx/httpx-0.28.0.ebuild b/dev-python/httpx/httpx-0.28.0.ebuild
deleted file mode 100644
index ce5c39fc1ade..000000000000
--- a/dev-python/httpx/httpx-0.28.0.ebuild
+++ /dev/null
@@ -1,106 +0,0 @@
-# Copyright 2022-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=hatchling
-PYTHON_COMPAT=( pypy3 python3_{10..13} )
-
-inherit distutils-r1 optfeature
-
-DESCRIPTION="Fully-featured HTTP client which provides sync and async APIs"
-HOMEPAGE="
-	https://www.python-httpx.org/
-	https://github.com/encode/httpx/
-	https://pypi.org/project/httpx/
-"
-SRC_URI="
-	https://github.com/encode/httpx/archive/${PV}.tar.gz
-		-> ${P}.gh.tar.gz
-"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
-IUSE="cli"
-
-RDEPEND="
-	dev-python/anyio[${PYTHON_USEDEP}]
-	dev-python/certifi[${PYTHON_USEDEP}]
-	=dev-python/httpcore-1*[${PYTHON_USEDEP}]
-	dev-python/idna[${PYTHON_USEDEP}]
-	cli? (
-		=dev-python/click-8*[${PYTHON_USEDEP}]
-		=dev-python/pygments-2*[${PYTHON_USEDEP}]
-		dev-python/rich[${PYTHON_USEDEP}]
-	)
-"
-# httptools cause tests to fail
-# https://github.com/encode/httpx/discussions/3429
-BDEPEND="
-	dev-python/hatch-fancy-pypi-readme[${PYTHON_USEDEP}]
-	test? (
-		dev-python/brotlicffi[${PYTHON_USEDEP}]
-		dev-python/chardet[${PYTHON_USEDEP}]
-		dev-python/cryptography[${PYTHON_USEDEP}]
-		dev-python/h2[${PYTHON_USEDEP}]
-		dev-python/socksio[${PYTHON_USEDEP}]
-		dev-python/trustme[${PYTHON_USEDEP}]
-		dev-python/typing-extensions[${PYTHON_USEDEP}]
-		dev-python/uvicorn[${PYTHON_USEDEP}]
-		>=dev-python/zstandard-0.18.0[${PYTHON_USEDEP}]
-		$(python_gen_cond_dep '
-			dev-python/trio[${PYTHON_USEDEP}]
-		' 3.{10..13})
-		!!dev-python/httptools[${PYTHON_USEDEP}]
-	)
-"
-
-distutils_enable_tests pytest
-
-src_prepare() {
-	local PATCHES=(
-		"${FILESDIR}/${PN}-0.27.0-opt-trio.patch"
-	)
-
-	if ! use cli; then
-		sed -i -e '/^httpx =/d' pyproject.toml || die
-	fi
-	sed -i -e '/rich/s:,<14::' pyproject.toml || die
-
-	distutils-r1_src_prepare
-}
-
-python_test() {
-	local args=()
-	local EPYTEST_DESELECT=(
-		# Internet
-		tests/client/test_proxies.py::test_async_proxy_close
-		tests/client/test_proxies.py::test_sync_proxy_close
-	)
-
-	if [[ ${EPYTHON} == pypy3 ]]; then
-		EPYTEST_DESELECT+=(
-			# https://github.com/encode/httpx/discussions/3430
-			# https://github.com/pypy/pypy/issues/5141
-			tests/test_config.py::test_load_ssl_with_keylog
-		)
-	fi
-
-	use cli || EPYTEST_IGNORE+=(
-		tests/test_main.py
-	)
-
-	if ! has_version "dev-python/trio[${PYTHON_USEDEP}]"; then
-		args+=( -o filterwarnings= -k "not trio" )
-	fi
-
-	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
-	epytest -p anyio "${args[@]}"
-}
-
-pkg_postinst() {
-	optfeature "HTTP/2 support" dev-python/h2
-	optfeature "SOCKS proxy support" dev-python/socksio
-	optfeature "Decoding for brotli compressed responses" dev-python/brotlicffi
-}