1 files changed, 0 insertions, 85 deletions
diff --git a/dev-python/sip/sip-4.16.9.ebuild b/dev-python/sip/sip-4.16.9.ebuild
deleted file mode 100644
index db18ecbf5aa9..000000000000
--- a/dev-python/sip/sip-4.16.9.ebuild
+++ /dev/null
@@ -1,85 +0,0 @@
-# Copyright 1999-2015 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Id$
-
-EAPI=5
-
-PYTHON_COMPAT=( python2_7 python3_{4,5} )
-
-inherit eutils python-r1 toolchain-funcs
-
-DESCRIPTION="Python extension module generator for C and C++ libraries"
-HOMEPAGE="http://www.riverbankcomputing.com/software/sip/intro https://pypi.python.org/pypi/SIP"
-SRC_URI="mirror://sourceforge/pyqt/${P}.tar.gz"
-
-# Sub-slot based on SIP_API_MAJOR_NR from siplib/sip.h.in
-SLOT="0/11"
-LICENSE="|| ( GPL-2 GPL-3 SIP )"
-KEYWORDS="alpha amd64 arm hppa ia64 ~ppc ppc64 ~sparc x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
-IUSE="debug doc"
-
-RDEPEND="${PYTHON_DEPS}"
-DEPEND="${RDEPEND}"
-
-REQUIRED_USE="
-	${PYTHON_REQUIRED_USE}
-"
-
-src_prepare() {
-	epatch "${FILESDIR}"/${PN}-4.15.5-darwin.patch
-
-	# Sub-slot sanity check
-	local sub_slot=${SLOT#*/}
-	local sip_api_major_nr=$(sed -nre 's:^#define SIP_API_MAJOR_NR\s+([0-9]+):\1:p' siplib/sip.h.in)
-	if [[ ${sub_slot} != ${sip_api_major_nr} ]]; then
-		eerror
-		eerror "Ebuild sub-slot (${sub_slot}) does not match SIP_API_MAJOR_NR (${sip_api_major_nr})"
-		eerror "Please update SLOT variable as follows:"
-		eerror "    SLOT=\"${SLOT%%/*}/${sip_api_major_nr}\""
-		eerror
-		die "sub-slot sanity check failed"
-	fi
-}
-
-src_configure() {
-	configuration() {
-		local myconf=(
-			"${PYTHON}"
-			"${S}"/configure.py
-			--destdir="$(python_get_sitedir)"
-			--incdir="$(python_get_includedir)"
-			$(use debug && echo --debug)
-			AR="$(tc-getAR) cqs"
-			CC="$(tc-getCC)"
-			CFLAGS="${CFLAGS}"
-			CFLAGS_RELEASE=
-			CXX="$(tc-getCXX)"
-			CXXFLAGS="${CXXFLAGS}"
-			CXXFLAGS_RELEASE=
-			LINK="$(tc-getCXX)"
-			LINK_SHLIB="$(tc-getCXX)"
-			LFLAGS="${LDFLAGS}"
-			LFLAGS_RELEASE=
-			RANLIB=
-			STRIP=
-		)
-		echo "${myconf[@]}"
-		"${myconf[@]}" || die
-	}
-	python_foreach_impl run_in_build_dir configuration
-}
-
-src_compile() {
-	python_foreach_impl run_in_build_dir default
-}
-
-src_install() {
-	installation() {
-		emake DESTDIR="${D}" install
-		python_optimize
-	}
-	python_foreach_impl run_in_build_dir installation
-
-	dodoc ChangeLog NEWS
-	use doc && dodoc -r doc/html
-}