blob: bfc4da4cc9d6631279c8677e7dee3079831aef06 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit toolchain-funcs
DESCRIPTION="An OCI container runtime monitor"
HOMEPAGE="https://github.com/containers/conmon"
if [[ ${PV} == 9999* ]]; then
inherit git-r3
EGIT_REPO_URI="https://github.com/containers/conmon.git"
else
SRC_URI="
https://github.com/containers/conmon/archive/v${PV}.tar.gz
-> ${P}.tar.gz
https://github.com/Flowdalic/conmon/commit/ff8794c5bc0805cc430229728befde16da47b68c.patch
-> ${PN}-2.1.11-make-docs-target-not-depend-on-install.tools.patch
"
KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv"
fi
LICENSE="Apache-2.0"
SLOT="0"
IUSE="+seccomp systemd"
RESTRICT="test"
RDEPEND="dev-libs/glib:=
seccomp? ( sys-libs/libseccomp )
systemd? ( sys-apps/systemd:= )"
DEPEND="${RDEPEND}"
BDEPEND="dev-go/go-md2man"
PATCHES=(
# https://github.com/containers/conmon/pull/507
"${DISTDIR}"/${PN}-2.1.11-make-docs-target-not-depend-on-install.tools.patch
)
src_prepare() {
# https://github.com/containers/conmon/pull/505
echo "${PV}" > VERSION || die
default
sed -i -e "s|shell.*--exists libsystemd.* && echo \"0\"|shell echo $(usex systemd 0 1)|g;" Makefile || die
echo -e "#!/usr/bin/env bash\necho $(usex seccomp 0 1)" > hack/seccomp-notify.sh || die
}
src_compile() {
tc-export CC PKG_CONFIG
export PREFIX="${EPREFIX}/usr" GOMD2MAN=$(command -v go-md2man)
default
}
src_install() {
default
dodir /usr/libexec/podman
dosym ../../bin/"${PN}" /usr/libexec/podman/"${PN}"
}
|
GitWeb
