app-crypt/libscrypt/libscrypt-1.22-r3.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit toolchain-funcs

DESCRIPTION="Shared library to implement the scrypt algorithm"
HOMEPAGE="https://github.com/technion/libscrypt"
SRC_URI="https://github.com/technion/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="BSD-2"
SLOT="0"
KEYWORDS="~amd64 arm arm64 ~hppa ~mips ppc ppc64 ~riscv sparc x86"

PATCHES=(
	"${FILESDIR}"/${PN}-1.22-no-clobber-fortify-source.patch
	"${FILESDIR}"/${PN}-1.22-aliasing.patch
)

src_prepare() {
	sed -i -e "s|ar rcs|$(tc-getAR) rcs|g" Makefile || die
	default
}

src_configure() {
	export PREFIX="${EPREFIX}"/usr
	export LIBDIR=${PREFIX}/$(get_libdir)
	export CFLAGS_EXTRA="${CFLAGS}"
	export LDFLAGS_EXTRA="${LDFLAGS}"
	unset CFLAGS
	unset LDFLAGS
}

src_compile() {
	emake CC="$(tc-getCC)"
}