dev-cpp/sol2/sol2-3.3.1-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68

# Copyright 2021-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

LUA_COMPAT=( lua5-{1,3,4} luajit )
inherit cmake lua

DESCRIPTION="Header-only C++ <-> Lua API wrapper"
HOMEPAGE="https://github.com/ThePhD/sol2"
SRC_URI="https://github.com/ThePhD/sol2/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
IUSE="test"
REQUIRED_USE="${LUA_REQUIRED_USE}"
RESTRICT="!test? ( test )"

DEPEND="
	${LUA_DEPS}
	test? (
		>=dev-cpp/catch-3
	)
"
BDEPEND="
	virtual/pkgconfig
"

PATCHES=(
	"${FILESDIR}"/sol2-3.3.0-werror.patch
	"${FILESDIR}"/sol2-3.2.2-luajit-pkgconf.patch
	"${FILESDIR}"/sol2-3.3.0-catch-depend.patch
	"${FILESDIR}"/sol2-3.3.0-cmake-dir.patch
	"${FILESDIR}"/sol2-3.3.0-dont-install-tests.patch
	"${FILESDIR}"/sol2-3.3.1-fix-emplace.patch
)

src_configure() {
	sol2_configure_wrapper() {
		local mycmakeargs=(
			-DSOL2_BUILD_LUA=no
			-DSOL2_TESTS=$(usex test)
			-DSOL2_LUA_VERSION="${ELUA}"
		)
		cmake_src_configure
	}
	lua_foreach_impl sol2_configure_wrapper
}

src_compile() {
	lua_foreach_impl cmake_src_compile
}

src_test() {
	sol2_test_wrapper() {
		if [[ ${ELUA} == luajit ]]; then
			einfo "Skipping test due to https://github.com/ThePhD/sol2/issues/1221"
		else
			cmake_src_test
		fi
	}
	lua_foreach_impl sol2_test_wrapper
}

src_install() {
	lua_foreach_impl cmake_src_install
}