blob: b939f27a34fdb2e581db21d9835e0c906e253b3d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{7..10} )
inherit python-r1 toolchain-funcs
DESCRIPTION="sip extension module for PyQt5"
HOMEPAGE="https://www.riverbankcomputing.com/software/sip/"
MY_PN=sip
MY_P=${MY_PN}-${PV/_pre/.dev}
if [[ ${PV} == *_pre* ]]; then
SRC_URI="https://dev.gentoo.org/~pesa/distfiles/${MY_P}.tar.gz"
else
SRC_URI="https://www.riverbankcomputing.com/static/Downloads/${MY_PN}/${PV}/${MY_P}.tar.gz"
fi
# Sub-slot based on SIP_API_MAJOR_NR from siplib/sip.h
SLOT="0/12"
LICENSE="|| ( GPL-2 GPL-3 SIP )"
KEYWORDS="amd64 arm arm64 ~ppc ~ppc64 x86"
IUSE=""
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
DEPEND="${PYTHON_DEPS}"
RDEPEND="${DEPEND}
!<dev-python/PyQt5-5.12.2
"
S=${WORKDIR}/${MY_P}
src_prepare() {
# Sub-slot sanity check
local sub_slot=${SLOT#*/}
local sip_api_major_nr=$(sed -nre 's:^#define SIP_API_MAJOR_NR\s+([0-9]+):\1:p' siplib/sip.h || die)
if [[ ${sub_slot} != ${sip_api_major_nr} ]]; then
eerror
eerror "Ebuild sub-slot (${sub_slot}) does not match SIP_API_MAJOR_NR (${sip_api_major_nr})"
eerror "Please update SLOT variable as follows:"
eerror " SLOT=\"${SLOT%%/*}/${sip_api_major_nr}\""
eerror
die "sub-slot sanity check failed"
fi
default
}
src_configure() {
configuration() {
local myconf=(
"${PYTHON}"
"${S}"/configure.py
--sip-module PyQt5.sip
--sysroot="${ESYSROOT}/usr"
--no-tools
AR="$(tc-getAR) cqs"
CC="$(tc-getCC)"
CFLAGS="${CFLAGS}"
CFLAGS_RELEASE=
CXX="$(tc-getCXX)"
CXXFLAGS="${CXXFLAGS}"
CXXFLAGS_RELEASE=
LINK="$(tc-getCXX)"
LINK_SHLIB="$(tc-getCXX)"
LFLAGS="${LDFLAGS}"
LFLAGS_RELEASE=
RANLIB=
STRIP=
)
echo "${myconf[@]}"
"${myconf[@]}" || die
}
python_foreach_impl run_in_build_dir configuration
}
src_compile() {
python_foreach_impl run_in_build_dir default
}
src_install() {
installation() {
emake DESTDIR="${D}" install
}
python_foreach_impl run_in_build_dir installation
einstalldocs
}
|
GitWeb