blob: 97c545afe105fe29f8dbb088e032e03d2ab4e72d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python2_7 python3_{6..9} )
PYTHON_REQ_USE='tk?,threads(+)'
inherit distutils-r1 toolchain-funcs
MY_PN=Pillow
MY_P=${MY_PN}-${PV}
DESCRIPTION="Python Imaging Library (fork)"
HOMEPAGE="https://python-pillow.org/"
SRC_URI="https://github.com/python-pillow/Pillow/archive/${PV}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/${MY_P}"
LICENSE="HPND"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ppc ppc64 sparc x86 ~amd64-linux ~x86-linux"
IUSE="examples imagequant jpeg jpeg2k lcms tiff tk truetype webp zlib"
RESTRICT="test"
RDEPEND="
dev-python/olefile[${PYTHON_USEDEP}]
imagequant? ( media-gfx/libimagequant:0 )
jpeg? ( virtual/jpeg:0 )
jpeg2k? ( media-libs/openjpeg:2= )
lcms? ( media-libs/lcms:2= )
tiff? ( media-libs/tiff:0=[jpeg,zlib] )
truetype? ( media-libs/freetype:2= )
webp? ( media-libs/libwebp:0= )
zlib? ( sys-libs/zlib:0= )"
DEPEND="${RDEPEND}
dev-python/setuptools[${PYTHON_USEDEP}]
"
distutils_enable_sphinx docs \
dev-python/sphinx_rtd_theme
python_configure_all() {
# It's important that these flags are also passed during the install phase
# as well. Make sure of that if you change the lines below. See bug 661308.
mydistutilsargs=(
build_ext
--disable-platform-guessing
$(use_enable truetype freetype)
$(use_enable jpeg)
$(use_enable jpeg2k jpeg2000)
$(use_enable lcms)
$(use_enable tiff)
$(use_enable imagequant)
$(use_enable webp)
$(use_enable webp webpmux)
$(use_enable zlib)
)
# setup.py sucks at adding the right toolchain paths but it does
# accept additional ones from INCLUDE and LIB so set these. You
# wouldn't normally need these at all as the toolchain should look
# here anyway but this setup.py does stupid things.
export \
INCLUDE=${ESYSROOT}/usr/include \
LIB=${ESYSROOT}/usr/$(get_libdir)
# We have patched in this env var.
tc-export PKG_CONFIG
}
python_install() {
python_doheader src/libImaging/*.h
distutils-r1_python_install
}
python_install_all() {
if use examples ; then
docinto example
dodoc docs/example/*
docompress -x /usr/share/doc/${PF}/example
fi
distutils-r1_python_install_all
}
|
GitWeb