blob: 75999c0d5fafd24eb502cf959445b5536bb262c1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
DISTUTILS_USE_SETUPTOOLS=rdepend
PYTHON_COMPAT=( pypy3 python{2_7,3_{6,7,8,9}} )
inherit distutils-r1
if [[ ${PV} == 9999 ]]; then
inherit git-r3
EGIT_REPO_URI="https://github.com/tqdm/tqdm"
else
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
KEYWORDS="~alpha ~amd64 ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
fi
DESCRIPTION="Add a progress meter to your loops in a second"
HOMEPAGE="https://github.com/tqdm/tqdm"
LICENSE="MIT"
SLOT="0"
IUSE="examples"
distutils_enable_tests nose
python_prepare_all() {
sed -r \
-e "s:'nose'(,[[:space:]]*|)::" \
-e "s:'flake8'(,[[:space:]]*|)::" \
-e "s:'coverage'(,[[:space:]]*|)::" \
-i setup.py
distutils-r1_python_prepare_all
}
python_test() {
# tests_main.py requires the package to be installed
distutils_install_for_testing
# Skip unpredictable performance tests
nosetests tqdm -v --ignore 'tests_perf.py' \
|| die "tests failed with ${EPYTHON}"
}
python_install() {
doman "${BUILD_DIR}"/lib/tqdm/tqdm.1
rm "${BUILD_DIR}"/lib/tqdm/tqdm.1 || die
distutils-r1_python_install --skip-build
}
python_install_all() {
if use examples; then
dodoc -r examples
docompress -x /usr/share/doc/${PF}/examples
fi
distutils-r1_python_install_all
}
|
GitWeb
