blob: 3ed30c63f90efc2433f05f5343abe6e5043f45e5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_EXT=1
DISTUTILS_USE_PEP517=poetry
PYTHON_COMPAT=( python3_{10..12} )
inherit distutils-r1 pypi
DESCRIPTION="Pure Python Multicast DNS Service Discovery Library (Bonjour/Avahi compatible)"
HOMEPAGE="
https://github.com/python-zeroconf/python-zeroconf/
https://pypi.org/project/zeroconf/
"
LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 x86 ~amd64-linux ~x86-linux"
RDEPEND="
>=dev-python/ifaddr-0.1.7[${PYTHON_USEDEP}]
$(python_gen_cond_dep '
>=dev-python/async-timeout-3.0.0[${PYTHON_USEDEP}]
' 3.10)
"
# the build system uses custom build script that uses distutils to build
# C extensions, sigh
BDEPEND="
>=dev-python/cython-3[${PYTHON_USEDEP}]
>=dev-python/setuptools-65.6.3[${PYTHON_USEDEP}]
test? (
dev-python/pytest-asyncio[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
export REQUIRE_CYTHON=1
python_test() {
local -x SKIP_IPV6=1
local EPYTEST_DESELECT=(
# network
tests/test_core.py::Framework::test_close_multiple_times
tests/test_core.py::Framework::test_launch_and_close
tests/test_core.py::Framework::test_launch_and_close_context_manager
# fragile to timeouts (?)
tests/services/test_browser.py::test_service_browser_expire_callbacks
tests/utils/test_asyncio.py::test_run_coro_with_timeout
)
epytest -o addopts=
}
|
GitWeb
