blob: cea98c0b38d6f47567a18a1b176a5c8008f584cc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
USE_RUBY="ruby24 ruby25 ruby26"
RUBY_FAKEGEM_RECIPE_TEST="rspec3"
RUBY_FAKEGEM_RECIPE_DOC="none"
RUBY_FAKEGEM_EXTRADOC="README.md"
RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
inherit ruby-fakegem
DESCRIPTION="HTTP/REST API client library with pluggable components"
HOMEPAGE="https://github.com/lostisland/faraday"
SRC_URI="https://github.com/lostisland/faraday/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="MIT"
SLOT="$(ver_cut 1)"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
IUSE=""
DEPEND+=" test? ( sys-process/lsof )"
ruby_add_rdepend ">=dev-ruby/multipart-post-1.2.0 <dev-ruby/multipart-post-3"
ruby_add_bdepend "test? (
>=dev-ruby/test-unit-2.4
>=dev-ruby/connection_pool-2.2.2
dev-ruby/rack
dev-ruby/webmock
)"
all_ruby_prepare() {
# Remove bundler support.
rm Gemfile || die
sed -i -e '/[Bb]undler/d ; 1irequire "yaml"' Rakefile || die
sed -i -e '/bundler/,/^fi/ s:^:#:' script/test || die
# Avoid loading all lib files since some of them require unpackaged dependencies.
sed -e '/[Cc]overall/ s:^:#:' \
-e '/lib\/\*\*/ s:^:#:' \
-e '/simplecov/ s:^:#:' \
-e '/SimpleCov/,/end/ s:^:#:' \
-e '/pry/ s:^:#:' \
-i spec/spec_helper.rb || die
# The proxy server is already killed, may be OS X vs Linux issue.
#sed -i -e '138 s/^/#/' script/test || die
sed -i -e '/git ls-files/ s:^:#:' ${RUBY_FAKEGEM_GEMSPEC} || die
# Avoid multipart tests that require an unpackaged dependency
# that appears to be no longer maintained.
rm -f spec/faraday/request/multipart_spec.rb || die
sed -e '/multipart_parser/ s:^:#:' \
-i spec/support/helper_methods.rb || die
# Remove specs for unpackaged adapters
rm -f spec/faraday/adapter/{em_http,em_synchrony,excon}_spec.rb || die
# Make this adapter optional since it comes with a long list of
# dependencies.
if ! has_version "dev-ruby/typhoeus:1" ; then
rm -f spec/faraday/adapter/typhoeus_spec.rb || die
fi
# Fix spec broken by newer rack versions, already fixed upstream
sed -i -e 's/one, two/name=value/' spec/support/shared_examples/request_method.rb || die
}
each_ruby_prepare() {
# Make sure the test scripts use the right ruby interpreter
sed -i -e 's:ruby:'${RUBY}':' script/* || die
}
each_ruby_test() {
MT_NO_PLUGINS=true each_fakegem_test
# Sleep some time to allow the sinatra test server to die
einfo "Waiting for test server to stop"
sleep 10
}
|
GitWeb