dev-ruby/octokit/octokit-4.22.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8
USE_RUBY="ruby26 ruby27 ruby30"

RUBY_FAKEGEM_RECIPE_DOC="yard"
RUBY_FAKEGEM_RECIPE_TEST="rspec3"
RUBY_FAKEGEM_EXTRADOC="README.md CONTRIBUTING.md"
RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"

inherit multilib ruby-fakegem

DESCRIPTION="Ruby toolkit for the Github API"
HOMEPAGE="https://github.com/octokit/octokit.rb"
SRC_URI="https://github.com/octokit/octokit.rb/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE=""

RUBY_S=octokit.rb-${PV}

ruby_add_rdepend "
	>=dev-ruby/faraday-0.9:*
	=dev-ruby/sawyer-0.8*
"

ruby_add_bdepend "test? (
	dev-ruby/jwt
	dev-ruby/mime-types
	>=dev-ruby/netrc-0.7.7
	>=dev-ruby/rbnacl-7.1.1:6
	dev-ruby/vcr[json]
	dev-ruby/webmock:3 )"

all_ruby_prepare() {
	sed -e '/if RUBY_ENGINE/,/^end/ s:^:#: ; 1igem "webmock", "~>3.0"' \
		-e '/pry/ s:^:#:' \
		-i spec/helper.rb || die
}