blob: 37a670a5b276f947e0f3805ac9043903f5452879 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit eutils flag-o-matic autotools
DESCRIPTION="New 3d engine based off of id Softwares's Quake and QuakeWorld game engine"
HOMEPAGE="http://www.quakeforge.net/"
SRC_URI="mirror://sourceforge/quake/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="alsa cdinstall debug dga fbcon flac ipv6 ncurses oss png sdl vorbis wildmidi X xdg xv zlib"
RESTRICT="userpriv"
RDEPEND="
media-libs/libsamplerate
net-misc/curl
virtual/opengl
alsa? ( media-libs/alsa-lib )
dga? ( x11-libs/libXxf86dga )
flac? ( media-libs/flac )
ncurses? ( sys-libs/ncurses:0 )
png? ( media-libs/libpng:0 )
sdl? ( media-libs/libsdl[video] )
vorbis? (
media-libs/libogg
media-libs/libvorbis
)
wildmidi? ( media-sound/wildmidi )
X? (
x11-libs/libX11
x11-libs/libXext
x11-libs/libXxf86vm
)
xv? (
x11-libs/libX11
x11-libs/libXext
x11-libs/libXxf86vm
)
zlib? ( sys-libs/zlib )"
DEPEND="${RDEPEND}
cdinstall? ( games-fps/quake1-data )
>=sys-devel/bison-2.6
sys-devel/flex
virtual/pkgconfig"
PATCHES=(
"${FILESDIR}"/${P}-gentoo.patch
)
src_prepare() {
default
eautoreconf
append-cflags -std=gnu89 # build with gcc5 (bug #570392)
}
src_configure() {
local debugopts
use debug \
&& debugopts="--enable-debug --disable-optimize --enable-profile" \
|| debugopts="--disable-debug --disable-profile"
local clients=${QF_CLIENTS}
use fbcon && clients="${clients},fbdev"
use sdl && clients="${clients},sdl"
use X && clients="${clients},x11"
[ "${clients:0:1}" == "," ] && clients=${clients:1}
local servers=${QF_SERVERS:-master,nq,qw,qtv}
local tools=${QF_TOOLS:-all}
econf \
--enable-dependency-tracking \
$(use_enable ncurses curses) \
$(use_enable vorbis) \
$(use_enable png) \
$(use_enable zlib) \
$(use_with ipv6) \
$(use_with fbcon fbdev) \
$(use_with X x) \
$(use_enable xv vidmode) \
$(use_enable dga) \
$(use_enable sdl) \
--disable-xmms \
$(use_enable alsa) \
$(use_enable flac) \
$(use_enable oss) \
$(use_enable xdg) \
$(use_enable wildmidi) \
--enable-sound \
--disable-optimize \
--disable-Werror \
--without-svga \
${debugopts} \
--with-global-cfg=/etc/quakeforge.conf \
--with-sharepath=/usr/share/quake1 \
--with-clients=${clients} \
--with-servers=${servers} \
--with-tools=${tools}
}
src_install() {
emake -j1 DESTDIR="${D}" install
dodoc ChangeLog NEWS TODO
}
pkg_postinst() {
# same warning used in quake1 / quakeforge / nprquake-sdl
echo
elog "Before you can play, you must make sure"
elog "${PN} can find your Quake .pak files"
elog
elog "You have 2 choices to do this"
elog "1 Copy pak*.pak files to /usr/share/quake1/id1"
elog "2 Symlink pak*.pak files in /usr/share/quake1/id1"
elog
elog "Example:"
elog "my pak*.pak files are in /mnt/secondary/Games/Quake/Id1/"
elog "ln -s /mnt/secondary/Games/Quake/Id1/pak0.pak /usr/share/quake1/id1/pak0.pak"
elog
elog "You only need pak0.pak to play the demo version,"
elog "the others are needed for registered version"
}
|
GitWeb