blob: 0afb14dee6249b008b6d67775fcc2f60cd8926c8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
GNOME_TARBALL_SUFFIX="bz2"
GNOME2_LA_PUNT="yes"
GNOME2_EAUTORECONF="yes"
inherit gnome2 multilib-minimal virtualx
DESCRIPTION="Library to construct graphical interfaces at runtime"
HOMEPAGE="https://library.gnome.org/devel/libglade/stable/"
LICENSE="LGPL-2"
SLOT="2.0"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
IUSE="static-libs test"
RESTRICT="!test? ( test )"
RDEPEND=">=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}]
>=x11-libs/gtk+-2.24.23:2[${MULTILIB_USEDEP}]
>=dev-libs/atk-2.10.0[${MULTILIB_USEDEP}]
>=dev-libs/libxml2-2.9.1-r4[${MULTILIB_USEDEP}]
"
DEPEND="${RDEPEND}"
BDEPEND="
dev-build/gtk-doc-am
virtual/pkgconfig
"
PATCHES=(
# patch to stop make install installing the xml catalog
# because we do it ourselves in postinst()
"${FILESDIR}"/Makefile.in.am-2.4.2-xmlcatalog.patch
# patch to not throw a warning with gtk+-2.14 during tests, as it triggers abort
"${FILESDIR}/${PN}-2.6.3-fix_tests-page_size.patch"
# Fails with gold due to recent changes in glib-2.32's pkg-config files
"${FILESDIR}/${P}-gold-glib-2.32.patch"
# Needed for solaris, else gcc finds a syntax error in /usr/include/signal.h
"${FILESDIR}/${P}-enable-extensions.patch"
)
src_prepare() {
if ! use test; then
sed 's/ tests//' -i Makefile.am Makefile.in || die "sed failed"
fi
# Deprecated macro that does nothing. Provided by gnome-base/gnome-common
# but adding an additional bdep for this is silly.
sed -i '/GNOME_COMMON_INIT/d' configure.in || die
gnome2_src_prepare
}
multilib_src_configure() {
export am_cv_pathless_PYTHON=none
ECONF_SOURCE=${S} \
gnome2_src_configure \
$(use_enable static-libs static)
if multilib_is_native_abi; then
ln -s "${S}"/doc/html doc/html || die
fi
}
multilib_src_test() {
virtx emake check || die "make check failed"
}
multilib_src_install() {
dodir /etc/xml
gnome2_src_install
}
multilib_src_install_all() {
local DOCS=( AUTHORS ChangeLog NEWS README )
einstalldocs
}
pkg_postinst() {
echo ">>> Updating XML catalog"
"${EPREFIX}"/usr/bin/xmlcatalog --noout --add "system" \
"https://glade.gnome.org/glade-2.0.dtd" \
"${EPREFIX}"/usr/share/xml/libglade/glade-2.0.dtd /etc/xml/catalog
gnome2_pkg_postinst
}
pkg_postrm() {
gnome2_pkg_postrm
echo ">>> removing entries from the XML catalog"
"${EPREFIX}"/usr/bin/xmlcatalog --noout --del \
"${EPREFIX}"/usr/share/xml/libglade/glade-2.0.dtd /etc/xml/catalog
}
|
GitWeb