blob: a0e5a1308d60d3e214127a2609e306de224f2023 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
ECM_HANDBOOK="forceoptional"
PYTHON_COMPAT=( python3_{6,7} )
PVCUT=$(ver_cut 1-3)
KFMIN=5.60.0
QTMIN=5.12.3
inherit python-single-r1 ecm kde.org
DESCRIPTION="Classical Mah Jongg for four players"
HOMEPAGE="https://kde.org/applications/games/kajongg/"
LICENSE="GPL-2" # TODO: CHECK
SLOT="5"
KEYWORDS="arm64"
IUSE=""
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
DEPEND="${PYTHON_DEPS}
>=kde-frameworks/kconfig-${KFMIN}:5
>=kde-frameworks/ki18n-${KFMIN}:5
>=kde-apps/libkdegames-${PVCUT}:5
>=dev-qt/qtgui-${QTMIN}:5
>=dev-qt/qtsvg-${QTMIN}:5
>=dev-qt/qtwidgets-${QTMIN}:5
dev-db/sqlite:3
$(python_gen_cond_dep '
dev-python/PyQt5[gui,svg,widgets,${PYTHON_MULTI_USEDEP}]
>=dev-python/twisted-16.6.0[${PYTHON_MULTI_USEDEP}]
')
"
RDEPEND="${DEPEND}
>=kde-apps/libkmahjongg-${PVCUT}:5
"
pkg_setup() {
python-single-r1_pkg_setup
ecm_pkg_setup
}
src_prepare() {
python_fix_shebang src
ecm_src_prepare
sed -i -e "/KDE_ADD_PYTHON_EXECUTABLE/s/^/#DONT/" CMakeLists.txt || die
}
src_install() {
ecm_src_install
dosym ../share/kajongg/kajongg.py /usr/bin/kajongg
dosym ../share/kajongg/kajonggserver.py /usr/bin/kajonggserver
fperms a+x /usr/share/kajongg/kajongg{,server}.py
}
|
GitWeb
