blob: a2ee5e08bf393e1260e794183e1e8d4add773a0b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
DISTUTILS_SINGLE_IMPL=1
DISTUTILS_USE_SETUPTOOLS=rdepend
PYTHON_COMPAT=( python3_{6,7,8} )
inherit distutils-r1
DESCRIPTION="Initial tagging script for Notmuch"
HOMEPAGE="https://github.com/afewmail/afew"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
LICENSE="ISC"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc"
RDEPEND="
$(python_gen_cond_dep '
dev-python/chardet[${PYTHON_USEDEP}]
dev-python/dkimpy[${PYTHON_USEDEP}]
net-mail/notmuch[python,${PYTHON_USEDEP}]
')"
BDEPEND="
$(python_gen_cond_dep '
dev-python/sphinx[${PYTHON_USEDEP}]
')"
DOCS=( "README.rst" )
python_prepare_all() {
sed -r \
-e "s/^([[:space:]]+)use_scm_version=.*,$/\1version='${PV}',/" \
-e "/^([[:space:]]+)setup_requires=.*,$/d" \
-i setup.py || die
distutils-r1_python_prepare_all
}
python_compile_all() {
esetup.py build_sphinx -b man --build-dir=docs/build
use doc && esetup.py build_sphinx -b html --build-dir=docs/build
}
python_install_all() {
doman docs/build/man/*
dodoc afew/defaults/afew.config
use doc && HTML_DOCS=( docs/build/html/. )
einstalldocs
}
|
GitWeb
