blob: 480100bb10f5f731fab9a2d117f300a07c902c43 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit user multilib systemd
DESCRIPTION="Open source DMARC implementation "
HOMEPAGE="http://www.trusteddomain.org/opendmarc/"
SRC_URI="mirror://sourceforge/opendmarc/${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha amd64 arm ~arm64 hppa ~ia64 ppc ppc64 sparc x86"
IUSE="spf +reports static-libs"
DEPEND="reports? ( dev-perl/DBI )
|| ( mail-filter/libmilter mail-mta/sendmail )"
RDEPEND="${DEPEND}
reports? (
dev-perl/DBD-mysql
dev-perl/HTTP-Message
dev-perl/Switch
)
spf? ( mail-filter/libspf2 )"
PATCHES=(
"${FILESDIR}"/${P}-multiple-From.patch
)
pkg_setup() {
enewgroup milter
enewuser milter -1 -1 /var/lib/milter milter
}
src_prepare() {
default
if use !reports ; then
sed -i -e '/^SUBDIRS =/s/reports//' Makefile.in || die
fi
}
src_configure() {
econf \
$(use_with spf) \
$(use_with spf spf2-include "${EPREFIX}"/usr/include/spf2) \
$(use_with spf spf2-lib "${EPREFIX}"/usr/$(get_libdir)) \
$(use_enable static-libs static)
}
src_install() {
default
use static-libs || rm -f "${ED}"/usr/$(get_libdir)/*.la
newinitd "${FILESDIR}"/opendmarc.initd opendmarc
newconfd "${FILESDIR}"/opendmarc.confd opendmarc
systemd_dounit "${FILESDIR}/${PN}.service"
dodir /etc/opendmarc
# create config file
sed \
-e 's:^# UserID .*$:UserID milter:' \
-e "s:^# PidFile .*:PidFile ${EPREFIX}/var/run/opendmarc/opendmarc.pid:" \
-e '/^# Socket /s:^# ::' \
"${S}"/opendmarc/opendmarc.conf.sample \
> "${ED}"/etc/opendmarc/opendmarc.conf \
|| die
}
|
GitWeb
