blob: 015af99350f1e22706c63b066dcd57eccc7e10ed (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools toolchain-funcs
MY_P=${P/graphicsm/GraphicsM}
DESCRIPTION="Collection of tools and libraries for many image formats"
HOMEPAGE="http://www.graphicsmagick.org/ https://foss.heptapod.net/graphicsmagick/graphicsmagick"
if [[ ${PV} == 9999 ]] ; then
EHG_REPO_URI="https://foss.heptapod.net/${PN}/${PN}"
inherit mercurial
else
VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/bobfriesenhahn.asc
inherit verify-sig
SRC_URI="https://downloads.sourceforge.net/project/${PN}/${PN}-history/$(ver_cut 1-2)/${MY_P}.tar.xz"
SRC_URI+=" verify-sig? ( https://downloads.sourceforge.net/project/${PN}/${PN}-history/$(ver_cut 1-2)/${MY_P}.tar.xz.asc )"
S="${WORKDIR}/${MY_P}"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
BDEPEND="verify-sig? ( sec-keys/openpgp-keys-bobfriesenhahn )"
fi
LICENSE="MIT"
SLOT="0/${PV%.*}"
IUSE="bzip2 +cxx debug dynamic-loading fpx heif imagemagick jbig jpeg jpeg2k jpegxl lcms lzma"
IUSE+=" openmp perl postscript png q16 q32 static-libs tcmalloc tiff truetype"
IUSE+=" webp wmf X zip zlib zstd"
RDEPEND="
dev-libs/libltdl
bzip2? ( app-arch/bzip2 )
fpx? ( media-libs/libfpx )
heif? ( media-libs/libheif:= )
imagemagick? ( !media-gfx/imagemagick )
jbig? ( media-libs/jbigkit )
jpeg? ( media-libs/libjpeg-turbo:= )
jpeg2k? ( media-libs/jasper:= )
jpegxl? ( media-libs/libjxl:= )
lcms? ( media-libs/lcms:2 )
lzma? ( app-arch/xz-utils )
perl? ( dev-lang/perl:= )
postscript? ( app-text/ghostscript-gpl:= )
png? ( media-libs/libpng:= )
tcmalloc? ( dev-util/google-perftools:= )
tiff? ( media-libs/tiff:= )
truetype? (
media-fonts/urw-fonts
>=media-libs/freetype-2
)
webp? ( media-libs/libwebp:= )
wmf? ( media-libs/libwmf )
X? (
x11-libs/libSM
x11-libs/libX11
x11-libs/libXext
)
zip? ( dev-libs/libzip:= )
zlib? ( sys-libs/zlib )
zstd? ( app-arch/zstd:= )
"
DEPEND="${RDEPEND}"
BDEPEND+=" virtual/pkgconfig"
PATCHES=(
"${FILESDIR}"/${PN}-1.3.41-flags.patch
"${FILESDIR}"/${PN}-1.3.41-perl.patch
)
pkg_pretend() {
[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
}
pkg_setup() {
[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
}
src_prepare() {
default
eautoreconf
}
src_configure() {
local depth=8
use q16 && depth=16
use q32 && depth=32
local myeconfargs=(
--enable-largefile
--enable-shared
$(use_enable static-libs static)
$(use_enable debug prof)
$(use_enable debug gcov)
$(use_enable imagemagick magick-compat)
$(use_enable openmp)
--with-threads
$(use_with dynamic-loading modules)
--with-quantum-depth=${depth}
--without-frozenpaths
$(use_with cxx magick-plus-plus)
$(use_with postscript gs)
$(use_with heif)
$(use_with jpegxl jxl)
$(use_with perl)
--with-perl-options=INSTALLDIRS=vendor
$(use_with bzip2 bzlib)
$(use_with fpx)
$(use_with jbig)
$(use_with webp)
$(use_with jpeg)
$(use_with jpeg2k jp2)
$(use_with lcms lcms2)
$(use_with lzma)
$(use_with png)
$(use_with tcmalloc)
$(use_with tiff)
--without-trio
$(use_with truetype ttf)
$(use_with wmf)
--with-fontpath="${EPREFIX}"/usr/share/fonts
--with-gs-font-dir="${EPREFIX}"/usr/share/fonts/urw-fonts
--with-windows-font-dir="${EPREFIX}"/usr/share/fonts/corefonts
$(use_with zip libzip)
$(use_with zlib)
$(use_with zstd)
$(use_with X x)
)
econf "${myeconfargs[@]}"
}
src_compile() {
default
use perl && emake perl-build
}
src_test() {
# Some perl tests fail when DISPLAY is set
unset DISPLAY
default
}
src_install() {
default
if use perl ; then
emake -C PerlMagick DESTDIR="${D}" install
find "${ED}" -type f -name perllocal.pod -exec rm -f {} + || die
find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} + || die
fi
find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} + || die
}
|
GitWeb