blob: de3827660c11257689965b6c7895a9798f8c31c7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit flag-o-matic toolchain-funcs portability multilib-minimal
MY_PN=${PN/-/_}
MY_P=${MY_PN}_${PV}
DESCRIPTION="The Linux Audio Developer's Simple Plugin API"
HOMEPAGE="https://www.ladspa.org/"
SRC_URI="https://www.ladspa.org/download/${MY_P}.tgz"
LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ppc ppc64 ~riscv sparc x86"
RDEPEND="media-libs/libsndfile[${MULTILIB_USEDEP}]"
DEPEND="${RDEPEND}"
S="${WORKDIR}/${MY_P}"
PATCHES=(
"${FILESDIR}/${P}-properbuild.patch"
)
HTML_DOCS="doc/*.html"
src_prepare() {
default
multilib_copy_sources
}
multilib_src_configure() {
# bug #911262
append-lfs-flags
}
multilib_src_compile() {
emake -C src CFLAGS="${CFLAGS}" CXXFLAGS="${CXXFLAGS}" \
DYNAMIC_LD_LIBS="$(dlopen_lib)" \
CC="$(tc-getCC)" CXX="$(tc-getCXX)" \
targets
}
multilib_src_test() {
emake -C src test
}
multilib_src_install() {
emake -C src INSTALL_PLUGINS_DIR="/usr/$(get_libdir)/ladspa" \
DESTDIR="${ED}" \
MKDIR_P="mkdir -p" \
install
}
multilib_src_install_all() {
einstalldocs
# Needed for apps like rezound
dodir /etc/env.d
echo "LADSPA_PATH=${EPREFIX}/usr/$(get_libdir)/ladspa" > "${ED}/etc/env.d/60ladspa"
}
|
GitWeb
