blob: dea37f7b001f26869060de8de335bece7a3b9a8c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
|
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit gnome2-utils xdg-utils
MY_P="${P/_/-}"
S="${WORKDIR}/${MY_P}"
DESCRIPTION="Audacious Player - Your music, your way, no exceptions"
HOMEPAGE="https://audacious-media-player.org/"
if [[ ${PV} == *9999 ]]; then
inherit autotools git-r3
EGIT_REPO_URI="https://github.com/audacious-media-player/audacious.git"
else
SRC_URI="
!gtk3? ( https://distfiles.audacious-media-player.org/${MY_P}.tar.bz2 )
gtk3? ( https://distfiles.audacious-media-player.org/${MY_P}-gtk3.tar.bz2 )"
KEYWORDS="~amd64 ~x86"
fi
SRC_URI+=" mirror://gentoo/gentoo_ice-xmms-0.2.tar.bz2"
LICENSE="BSD-2"
SLOT="0"
IUSE="gtk gtk3 nls qt5"
REQUIRED_USE="^^ ( gtk gtk3 qt5 )"
RDEPEND="
>=dev-libs/dbus-glib-0.60
>=dev-libs/glib-2.28
>=x11-libs/cairo-1.2.6
>=x11-libs/pango-1.8.0
virtual/freedesktop-icon-theme
gtk? ( x11-libs/gtk+:2 )
gtk3? ( x11-libs/gtk+:3 )
qt5? (
dev-qt/qtcore:5
dev-qt/qtgui:5
dev-qt/qtwidgets:5
)"
DEPEND="${RDEPEND}
virtual/pkgconfig
nls? ( dev-util/intltool )"
PDEPEND="~media-plugins/audacious-plugins-${PV}"
src_unpack() {
default
if use gtk3; then
mv "${MY_P}"{-gtk3,} || die
fi
[[ ${PV} == *9999 ]] && git-r3_src_unpack
}
src_prepare() {
default
[[ ${PV} == *9999 ]] && eautoreconf
}
src_configure() {
# D-Bus is a mandatory dependency, remote control,
# session management and some plugins depend on this.
# Building without D-Bus is *unsupported* and a USE-flag
# will not be added due to the bug reports that will result.
# Bugs #197894, #199069, #207330, #208606
econf \
--disable-valgrind \
--enable-dbus \
$(use_enable $(usex gtk gtk gtk3) gtk) \
$(use_enable nls) \
$(use_enable qt5 qt)
}
src_install() {
default
# Gentoo_ice skin installation; bug #109772
insinto /usr/share/audacious/Skins/gentoo_ice
doins -r "${WORKDIR}"/gentoo_ice/.
docinto gentoo_ice
dodoc "${WORKDIR}"/README
}
pkg_postinst() {
xdg_desktop_database_update
gnome2_icon_cache_update
}
pkg_postrm() {
xdg_desktop_database_update
gnome2_icon_cache_update
}
|
GitWeb