media-sound/munt-mt32emu-alsadrv/munt-mt32emu-alsadrv-2.3.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

inherit toolchain-funcs prefix

MY_P="munt_${PV//./_}"
DESCRIPTION="ALSA MIDI driver for emulating the Roland MT-32, CM-32L, CM-64 and LAPC-I"
HOMEPAGE="https://github.com/munt/munt"
SRC_URI="https://github.com/munt/munt/archive/${MY_P}.tar.gz"
LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="X"

DEPEND="media-libs/alsa-lib
	media-libs/munt-mt32emu
	X? (
		x11-libs/libX11
		x11-libs/libXpm
		x11-libs/libXt
	)"

RDEPEND="${DEPEND}"

S="${WORKDIR}/munt-${MY_P}/mt32emu_alsadrv"
DATA="/usr/share/mt32-rom-data"

src_prepare() {
	default

	# Fix MT32 ROM path.
	hprefixify src/alsadrv.cpp
}

src_compile() {
	emake mt32d CXX="$(tc-getCXX)" CXXFLAGS="${CXXFLAGS} ${LDFLAGS}"
	use X && emake xmt32 CXX="$(tc-getCXX)" CXXFLAGS="${CXXFLAGS} ${LDFLAGS}"
}

src_install() {
	dobin mt32d
	use X && dobin xmt32
	dodoc {AUTHORS,README}.txt
	keepdir "${DATA}"
}

pkg_postinst() {
	einfo "MT32_CONTROL.ROM and MT32_PCM.ROM cannot be legally included so you must"
	einfo "obtain them and place them in ${EPREFIX}${DATA}."
}